按特定顺序合并文件夹中的所有文档并对合并的输出进行排序

Question

我不是程序员，我只是安装活动 perl。 我在哪里可以找到执行以下操作的信息。

在一个文件夹中，我有各种 txt 文档， 我想合并前两个并以 stable 方式对结果进行排序 并将其另存为一个名为 : 合并的子文件夹中的新文档。

然后对以下 txt 文档，其他 2 个文档执行相同操作。 这样直到完成所有文件。

---

目录中的文件如下所示。

subtitle(english).txt
subtitle(spanish).txt
othername1(english).txt
othername1(spanish).txt
etc etc

它们被放置，下面的英文版和西班牙文版如果按字母顺序排序。

我需要先合并两个，然后是其他的（当时是两个，这样它就不会混合数据）

将两者合并后，合并后的内容如下所示：

1.- <english> hi 
1.- <spanish> hola.
2.- <english> thanks
2.- <spanish> gracias

因为每个文件中的原始顺序例如是英文。

1.- <english> hi
2.- <english> thanks

谢谢 关于输出名称，可以是任何名称，也可以是与英语或西班牙语相同的名称，表示第一个或第二个文件。

Answer 1

我认为这应该适合你，但我不能轻易测试它。

use strict;
use warnings;
use autodie;

my @files = do {
  opendir my $dh, '.';
  sort grep /\.txt\z/, grep -f, readdir $dh;
};

my $re = qr/\A ( [^()]+? ) \s* \( \s* ( .+ ) \s* \) [^()]+ \z /ix;

my @badfiles = grep $_ !~ $re, @files;
if (@badfiles) {
  print STDERR "These file names do not match the expected pattern\n";
  print STDERR "  $_\n" for @badfiles;
  print STDERR "\n";
  die "Invalid input files";
}

mkdir 'merged' unless -d 'merged';

while (@files > 1) {

  my @files = splice @files, 0, 2;
  my @fh = map { open my $fh, '<', $_; $fh } @files;
  my @details = map [ $_ =~ $re ], @files;
  my $newfile = sprintf "merged/%s(%s-%s).txt",
      $details[0][0],
      $details[0][1],
      $details[1][1];

  printf "%s + %s => %s ... ", @files, $newfile;

  open my $out_fh, '>', $newfile;
  until (grep eof, @fh) {
    print $out_fh scalar readline $_ for @fh;
  }
  close $out_fh;

  print "done\n";
}