根据一系列单元格的列中的值合并单元格

Question

如果 E 行具有相同的字符串，我需要在 G 行中添加数据，并在 A 行中合并日期。我找到了Excel VBA - Combine rows with duplicate values in one cell and merge values in other cell，这很有帮助，但我需要在 G7:G65536 范围内这样做，因为我从 1 到 6 的行已合并。

有什么方法可以调整这段代码吗？

我试图玩弄它，但它没有给我任何结果。

Answer 1

我使用你们的 cmets 得出以下示例数据。

    

我怀疑这个想法是使用列 E 作为唯一键列并聚合（又名 SUM）列 G 中的数量，同时构建一个串联的日期列表来自 A 列。Worksheet.UsedRange property 的前 6 行将被忽略，因为在前六行中至少有一些 Range.MergeCells property 与 Areas property 连接。 TBH，我发现您的原始叙述与您最近的 cmets 相矛盾，因此我将后者用作“发现”。

Sub merge_some_row_data()
    Dim rw As Long, lr As Long, s As Long, str As String

    Application.ScreenUpdating = False
    With ActiveSheet.Cells(1, 1).CurrentRegion
        With .Cells(7, 1).Resize(.Rows.Count - 6, .Columns.Count)
            .Cells.Sort Key1:=.Columns(5), Order1:=xlAscending, _
                        Key2:=.Columns(1), Order2:=xlAscending, _
                        Orientation:=xlTopToBottom, Header:=xlNo
        End With
        lr = .Rows.Count
        For rw = .Rows.Count To 7 Step -1
            If .Cells(rw, "E").Value2 <> .Cells(rw - 1, "E").Value2 And rw < lr Then
                .Cells(rw, "G") = Application.Sum(.Range(.Cells(rw, "G"), .Cells(lr, "G")))
                str = vbNullString
                For s = rw To lr
                    str = str & Chr(59) & .Cells(s, "A").Text    'Chr(59) is the ASCII code for a semi-colon
                Next s
                .Cells(rw, "A") = Mid(str, 2)  'truncate off the firsty semi-colon
                .Cells(rw + 1, 1).Resize(lr - rw, 1).EntireRow.Delete
                lr = rw - 1
            End If
        Next rw
    End With
    Application.ScreenUpdating = True
End Sub

运行代码后，结果如下所示。

    

如果您出于自己的超级机密目的而在转录此框架时遇到任何问题，请随时使用经过编辑的示例数据以及预期结果以及此代码中您无法适应自己情况的部分来修改您的原始问题.