如何从excel调用VBA函数

Question

我有一个 excel 文件，我必须在其中放置验证规则。我有一个单元格说“客户时间”，用户可以在其中输入时间，但它是自定义时间。用户可以这样输入时间

23:45
98:20
100:30

用户不能输入字符串和除冒号以外的特殊字符。我制作了一个宏，它可以根据客户需求完美运行。这是宏

Public Function isValidTime(myText) As String
Dim regEx
Set regEx = New RegExp   'Regular expression object
regEx.Pattern = "^[0-9]+([:]+[0-9]+)*$"  ' Set pattern.
If regEx.test(myText) Then
isValidTime = myText
Else
isValidTime = "Null"
End If
End Function

注意：要测试此宏，您必须在 Tool 中转到 VBA ide，然后引用，然后选择 microsoft visual basic vbascript 5.5

现在我想在 excel 中调用它。我可以像 =IsValidTime("23:43") 一样调用并获得结果，但客户对此不感兴趣。客户需要一个excel，他/她在其中输入值，值将根据上述标准进行验证并获得确切的值或Null。

我不知道如何解决这个任务。我也从数据中验证了日期和时间，然后是数据验证并设置了规则，它工作得很好，我的这条规则也需要同样的方法。任何帮助将不胜感激...

谢谢 卡兹米

Answer 1

您可以在工作表内使用Worksheet_Change 事件。在 VBE 中，选择工作表并从左侧下拉列表中选择 Workhseet，从右侧选择 Change。

输入以下代码：

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)

If Target.Address = "$A$1" Then 'assumes user input cell is A1

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    On Error GoTo ErrTrap

    Target.Value = isValidTime(Target.Value)

End If

KeepMoving:

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With

    Exit Sub 

ErrTrap:

    MsgBox Err.Number & Err.Description
    Resume KeepMoving


End Sub

Public Function isValidTime(myText) As String

Dim regEx

Set regEx = New RegExp   'Regular expression object

regEx.Pattern = "^[0-9]+([:]+[0-9]+)*$"  ' Set pattern.

If regEx.test(myText) Then

    isValidTime = myText

Else
    isValidTime = "Null"

End If

End Function