创建循环索引并将索引工作表中的数据复制到 Master

Question

我要做的是从所有工作表中复制可变数据范围，但标题相同，然后一个接一个地粘贴到主工作表中。每当我单击另一张工作表并返回主控时，原始代码（下面的代码 1）都会更新主控中的数据。现在的问题是工作簿中还有其他工作表我不想包含在复制过程中。

我已经编辑了下面收到的代码（下面的代码 2），以尝试定义开始和结束表以运行“循环索引”，并删除“复制标题”代码行，因为每个工作表的标题都出现在整个过程中母版。显然它不起作用，我想知道是否有人可以提供帮助。

您能帮我更正合并后的代码或提供更优雅的解决方案吗？谢谢。

这里的原始问题 - Excel Forum post

此处的辅助代码 - Stack post LoopIndex

原始代码 1

Private Sub Worksheet_Activate()
Dim ws As Worksheet

Application.ScreenUpdating = False
Me.UsedRange.Clear

For Each ws In ThisWorkbook.Worksheets
If ws.Name <> Me.Name Then
    If Range("A1") = "" Then ws.Range("A1").EntireRow.Copy Me.Range("A1")'copy in the headers
    ws.UsedRange.Offset(1).Copy Me.Range("A" & Rows.Count).End(xlUp).Offset(1)'copy data
End If
Next ws

Application.ScreenUpdating = True
End Sub

编辑代码 2

Private Sub Worksheet_Activate()
Dim ws As Worksheet

Application.ScreenUpdating = False
Me.UsedRange.Clear

Dim StartIndex, EndIndex, LoopIndex As Integer
   StartIndex = Sheets("Master sheet").Index + 1
   EndIndex = Sheets("End").Index - 1

For LoopIndex = StartIndex To EndIndex

    If Range("A1") = "" Then ws.Range("A1").Offset(1).Copy Me.Range("A" &Rows.Count).End(xlUp).Offset(1)  'copy data
Next LoopIndex

Application.ScreenUpdating = True
End Sub

Answer 1

当只有一个源工作表时，我几乎可以理解为什么您将其作为针对工作表“主列表”的工作表激活事件例程。当您有多个源工作表时，我很难将其视为方便。我不是要你证明你的决定是正确的，因为我对工作簿没有完全了解，但你可能想重新考虑你的方法。我已将下面的例程编码为普通宏，但您可以根据需要轻松更改。

我不喜欢假设要加载的工作表是从Sheets("Master sheet").Index + 1 到Sheets("End").Index - 1 的方法。尽管我从未尝试过这种方法，但我会认为这是不稳定的。

我创建了一个隐藏的工作表“加载列表”：

这会按要加载的顺序列出要加载的工作表。

我已经用数据填写了工作表“Sheet1”：

不是很有想象力的数据，但它可以很容易地检查“主列表”是否加载了正确的数据。工作表“Sheet2”到“Sheet5”具有相似的数据，只是数据行数不同，并且“S1”被“S2”、“S3”、“S4”和“S5”替换。

宏运行后，“主列表”顶部包含：

您可以看到我已经加载了第一个工作表中的所有行，然后只加载了后续工作表中的数据行。

关于我使用的 VBA，我并没有说太多。一旦你知道一个语句存在，通常很容易查找它。必要时询问。我希望我已经对代码的作用提供了充分的解释。有需要再问。

Option Explicit
Sub CombinedSelected()

  Dim ColSrcMax As Long
  Dim LoadList As Variant
  Dim RowListCrnt As Long
  Dim RowListMax As Long
  Dim RowMasterNext As Long
  Dim RowSrcMax As Long

  With Worksheets("Load List")
    RowListMax = .Cells(Rows.Count, "A").End(xlUp).Row
    ' Load the values from column A of worksheet "Load List" to LoadList.
    ' The statement converts LoadList to a 2 dimensional array. It is the
    ' equivalent of Redim LoadList(1 To RowListMax, 1 to 1)
    LoadList = .Range(.Cells(1, "A"), .Cells(RowListMax, "A")).Value
  End With

  RowMasterNext = 1

  With Worksheets("Master sheet")
    .Cells.EntireRow.Delete     ' Delete existing contents
  End With

  For RowListCrnt = 2 To RowListMax
    With Worksheets(LoadList(RowListCrnt, 1))
      ' Find last used row and column containing a value.
      ' Warning.  These statements do not allow for any of the source worksheets being empty
      RowSrcMax = .Cells.Find("*", .Range("A1"), xlFormulas, , xlByRows, xlPrevious).Row
      ColSrcMax = .Cells.Find("*", .Range("A1"), xlFormulas, , xlByColumns, xlPrevious).Column
      If RowListCrnt = 2 Then
        ' For first source worksheet only include header row
        .Range(.Cells(1, 1), .Cells(RowSrcMax, ColSrcMax)).Copy _
               Destination:=Worksheets("Master sheet").Cells(RowMasterNext, 1)
        RowMasterNext = RowMasterNext + RowSrcMax
      Else
        ' Data rows only to be copied
        .Range(.Cells(2, 1), .Cells(RowSrcMax, ColSrcMax)).Copy _
               Destination:=Worksheets("Master sheet").Cells(RowMasterNext, 1)
        RowMasterNext = RowMasterNext + RowSrcMax - 1
      End If
    End With
  Next

End Sub