从哈希值生成组合答案

【问题标题】：generate combinations from hash values从哈希值生成组合
【发布时间】：2016-04-15 05:22:52
【问题描述】：

如果我有哈希，则在 perl 中

my %ranges = (                                                                                      
'--tic' => [ 0, 1, 2 ],                                                                             
'--threads' => [ 8, 16 ],                                                                           
'--level' => [ 10, 20 ]                                                                               
);

如何生成所有组合的数组，例如

--level 10 --threads 8 --tic 0                                                                        
--level 10 --threads 8 --tic 1                                                                        
--level 10 --threads 8 --tic 2                                                                        
--level 10 --threads 16 --tic 0                                                                       
--level 10 --threads 16 --tic 1                                                                       
--level 10 --threads 16 --tic 2                                                                       
--level 20 --threads 8 --tic 0                                                                        
--level 20 --threads 8 --tic 1                                                                        
--level 20 --threads 8 --tic 2                                                                        
--level 20 --threads 16 --tic 0                                                                       
--level 20 --threads 16 --tic 1                                                                       
--level 20 --threads 16 --tic 2

可以有任意数量的哈希条目，每个条目的值数组中可以有任意数量的元素。输出数组的顺序无关紧要，每个组合只需要 1 个元素，在这种情况下为 3*2*2 = 12，但可以是任意数字。

我认为 splice、map 和 foreach 的某种组合应该可以工作，但我正在以一种糟糕的方式寻找它。

【问题讨论】：

您正在尝试生成所谓的笛卡尔积（或叉积）； CPAN 上有几个模块可以帮助解决这个问题。

标签： perl hash

【解决方案1】：

如前所述，您正在寻找Cartesian product，

use strict;
use warnings;

sub getCartesian {
#
  my @input = @_;
  my @ret = map [$_], @{ shift @input };

  for my $a2 (@input) {
    @ret = map {
      my $v = $_;
      map [@$v, $_], @$a2;
    }
    @ret;
  }
  return @ret;
}

my %ranges = (
    '--tic' => [ 0, 1, 2 ],
    '--threads' => [ 8, 16 ],
    '--level' => [ 10, 20 ]
);

my @arr =  map {
  my $k = $_;
  [ map "$k $_", @{$ranges{$k}} ];
}
keys %ranges;

print "@$_\n" for getCartesian(@arr);

输出

--level 10 --tic 0 --threads 8
--level 10 --tic 0 --threads 16
--level 10 --tic 1 --threads 8
--level 10 --tic 1 --threads 16
--level 10 --tic 2 --threads 8
--level 10 --tic 2 --threads 16
--level 20 --tic 0 --threads 8
--level 20 --tic 0 --threads 16
--level 20 --tic 1 --threads 8
--level 20 --tic 1 --threads 16
--level 20 --tic 2 --threads 8
--level 20 --tic 2 --threads 16

【讨论】：

【解决方案2】：

Set::Product 模块将为您完成这项工作

这是一个示例程序

use strict;
use warnings 'all';

use Set::Product 'product';

my %ranges = (
    '--tic'     => [ 0, 1, 2 ],
    '--threads' => [ 8, 16 ],
    '--level'   => [ 10, 20 ],
);

my @keys = sort keys %ranges;

product {
    print join(' ', map { "$keys[$_] $_[$_]" } 0 .. $#keys), "\n";
} @ranges{@keys};

输出

--level 10 --threads 8 --tic 0
--level 10 --threads 8 --tic 1
--level 10 --threads 8 --tic 2
--level 10 --threads 16 --tic 0
--level 10 --threads 16 --tic 1
--level 10 --threads 16 --tic 2
--level 20 --threads 8 --tic 0
--level 20 --threads 8 --tic 1
--level 20 --threads 8 --tic 2
--level 20 --threads 16 --tic 0
--level 20 --threads 16 --tic 1
--level 20 --threads 16 --tic 2

【讨论】：