带有可选键的模式匹配映射

Question

我有一个函数可以接收带有许多键的地图，其中一些是可选的。如何编写理解映射的函数签名，同时允许可选键默认为某些东西？

def handle_my_map(%{text: text, 
                    print_times: print_times, # this I want to default to 2
                    color: color # this I want to default to "Blue"
  }) do
  Enum.each(1..print_times, fn (_) -> IO.puts ["(", color, "): ", text] end)
end

Test.handle_my_map(%{text: "here", print_times: 5, color: "Red"})
# (Red): here
# (Red): here
# (Red): here
# (Red): here
# (Red): here

handle_my_map(%{text: "there"})
# => MatchError!

我希望它是：

handle_my_map(%{text: "where", print_times: 3})
# (Blue): where
# (Blue): where
# (Blue): where
handle_my_map(%{text: "there"})
# (Blue): there
# (Blue): there

类似于 ruby​​ 的关键字参数：

def handle_my_map(text: nil, print_times: 2, color: 'Blue')

Answer 1

你可以使用Map.merge/2:

defmodule Handler do
  @defaults %{print_times: 2, color: "Blue"}

  def handle_my_map(map) do
    %{text: text, print_times: times, color: color} = merge_defaults(map)
    Enum.each(1..times, fn (_) -> IO.puts ["(", color, "): ", text] end)
  end

  defp merge_defaults(map) do
    Map.merge(@defaults, map)
  end
end

如果要允许 nils，可以使用 Map.merge/3 并将 merge_defaults/1 更改为：

defp merge_defaults(map) do
  Map.merge(@defaults, map, fn _key, default, val -> val || default end)
end

Answer 2

我可能会选择这样的东西：

defmodule Handler do
  @defaults %{print_times: 2, color: "Blue"}

  def handle_my_map(map) do
    %{text: text, print_times: times, color: color} = Dict.put_new(map, @defaults)
    Enum.each(1..times, fn (_) -> IO.puts ["(", color, "): ", text] end)
  end
end

如果您需要使用现有键处理 nil 值，您可以这样做：

defmodule Handler do
  @defaults %{print_times: 2, color: "Blue"}

  def handle_my_map(map) do
    %{text: text, print_times: times, color: color} = @defaults
    |> Dict.merge(map)
    |> Enum.into %{}, fn
      {key, nil} -> {key, @defaults[key]}
      {key, val} -> {key, val}
    end

    Enum.each(1..times, fn (_) -> IO.puts ["(", color, "): ", text] end)
  end
end

Answer 3

嗯。我认为您需要编写另一个带有参数%{a: a, b: b} 的handle_my_map 函数。像这样：

  def handle_my_map(%{a: a, b: b, optional_c: c}) do
    a + b + c
  end

  def handle_my_map(%{a: a, b: b}) do
    a + b
  end

  YourModule.handle_my_map %{a: 1, b: 2}
  #=> 3
  YourModule.handle_my_map %{a: 1, b: 2, optional_c: 3}
  #=> 6

Elixir 将搜索与您的参数匹配的函数 handle_my_map，直到具有 arity 1 的函数结束