我无法使用 querySelector 单击链接

Question

我想通过选择特定日期从网站下载文件。检查显示 href 内容的元素，但无法点击它。

网页代码

<td>
<a href="/content/historical/EQUITIES/2021/FEB/cm02FEB2021bhav.csv.zip" target="new">cm02FEB2021bhav.csv.zip</a><br>
</td>

我的 VBA 代码

Dim files As String

Dim IE As Object
Set IE = CreateObject("InternetExplorer.Application")
IE.navigate "https://www1.nseindia.com/products/content/equities/equities/archieve_eq.htm"
IE.Visible = True
While IE.readystate <> 4: DoEvents: Wend


Do

Set el = Nothing
On Error Resume Next
Set el = IE.document.getelementbyid("h_filetype")
On Error GoTo 0
DoEvents
Loop While el Is Nothing
IE.document.getelementbyid("h_filetype").Value = "eqbhav"

Do

Set el = Nothing
On Error Resume Next
Set el = IE.document.getelementbyid("date")
On Error GoTo 0
DoEvents
Loop While el Is Nothing
IE.document.getelementbyid("date").Value = "02-02-2021

IE.document.parentWindow.execScript "validateInput();", "javascript"

IE.document.querySelector("a[href^='/content/historical/EQUITIES/']").Click

我已经尝试了下面的代码，但它不起作用。

IE.document.querySelector("a[href^='/content/historical/EQUITIES/']").Click

Answer 1

您的 QuerySelector .querySelector("a[href^='/content/historical/EQUITIES/']") 无法工作，因为 /content/historical/EQUITIES/ 只是 url 的一部分。另一个原因是，在执行完 JS 之后，你必须让文档有机会生成想要的 url。

我已经完成了您的代码，直到 Click。然后，您必须再次等待一段时间，以便在 IE 底部显示带有保存按钮的栏。然后你必须使用SendKeys() 来触发保存。然后该文件将在 IE 的默认下载文件夹中结束。如果没有设置额外的文件夹，这是系统文件夹Downloads。

Sub TestClick()

Dim files As String
Dim IE As Object
Dim el As Object

  Set IE = CreateObject("InternetExplorer.Application")
  IE.navigate "https://www1.nseindia.com/products/content/equities/equities/archieve_eq.htm"
  IE.Visible = True
  While IE.readystate <> 4: DoEvents: Wend
  
  Do
    Set el = Nothing
    On Error Resume Next
    Set el = IE.document.getelementbyid("h_filetype")
    On Error GoTo 0
    DoEvents
  Loop While el Is Nothing
  IE.document.getelementbyid("h_filetype").Value = "eqbhav"
  Do
    Set el = Nothing
    On Error Resume Next
    Set el = IE.document.getelementbyid("date")
    On Error GoTo 0
    DoEvents
  Loop While el Is Nothing
  IE.document.getelementbyid("date").Value = "02-02-2021"
  IE.document.parentWindow.execScript "validateInput();", "javascript"
  
  'You must spend time to generate the link you want
  Do
    Set el = Nothing
    On Error Resume Next
    Set el = IE.document.getelementbyid("spanDisplayBox").getElementsByTagName("a")(0)
    On Error GoTo 0
    DoEvents
  Loop While el Is Nothing
  'Than you can click it
  el.Click
  
  'Here more of your code
  '...
End Sub