在批处理文件上使用驱动器号

Question

我使用脚本扫描整个用户的驱动器 C 以查找特定文件，然后将结果记录在网络上的 txt 中。它就像一个魅力。

这是脚本：

@echo off

pushd C:\
dir /s /a-d "setup.txt" /s "setup2.txt" >nul && (goto printresult) || (goto notfound)

:printresult
dir /s /a-d setup.txt /s setup2.txt >>"\\servidor\pastadelogs\FOUND_%computername%.txt
popd
exit

:notfound
echo "Este PC não possui os arquivos" >>"\\servidor\pastadelogs\NOTFOUND_%computername%.txt
popd
exit

现在我需要对其进行改进，使其也能在 USB 驱动器内进行扫描。我已经有一个可以给我 USB 字母的代码：

  @echo off
for /F "usebackq tokens=1,2,3,4 " %%i in (`wmic logicaldisk get caption^,description^,drivetype 2^>NUL`) do (

    if %%l equ 2 (
    echo %%i is a drive letter

        )
        )

我的两个问题是：

• 可以一起使用吗？
• 如果插入了多个 USB 怎么办？它将如何运作？我可以为每个驱动器号结果设置 1 个变量吗？

最好的问候

Answer 1

因为任务也在扫描慢速 USB 介质，所以明智的做法是在第一次通过时创建一个带有结果的文件，如果有结果，只需 type 将数据写入目标文件，而不是再次进行扫描.

这是未经测试的，将检查可移动和本地磁盘：（不包括 A: 和 B:）

已编辑

这使用了一种选择不包括哪些驱动器等的方法（在 findstr 命令中）：例如驱动器号和驱动器类型号，ID 删除了标题。

@echo off
set "file=%temp%\drivescan.tmp"
for /f "tokens=1,2" %%a in ('wmic logicaldisk get deviceid^,drivetype^|findstr /i /v "a: b: 0 1 4 5 6 ID"') do (
    echo Processing drive %%a
    (dir /b /s /a-d "%%a\setup.txt" "%%a\setup2.txt")>"%file%" 2>nul
    for %%d in ("%file%") do if %%~zd NEQ 0 (
      type "%file%" >> "\\servidor\pastadelogs\FOUND_%computername%.txt"
        ) else (
      echo "[%%a] Este PC não possui os arquivos">>"\\servidor\pastadelogs\NOTFOUND_%computername%.txt"
    )
    del "%file%" 2>nul
)

这是我在 Google 上搜索的驱动器类型列表：

wmic logicaldisk where drivetype=2 get deviceid, volumename, description

Types

0 => Unknown
1 => No Root Directory
2 => Removable Disk
3 => Local Disk
4 => Network Drive
5 => Compact Disc
6 => RAM Disk

Answer 2

@echo off
for /f %%i in ('wmic logicaldisk where "drivetype=2" get caption^|find ":"') do (
  pushd %%i
    dir /s /a-d "setup.txt" /s "setup2.txt" >nul && (
      dir /b /s /a-d setup.txt /s setup2.txt >>"\\servidor\pastadelogs\FOUND_%computername%.txt"
    ) || (
      echo "[%%i] Este PC não possui os arquivos" >>"\\servidor\pastadelogs\NOTFOUND_%computername%.txt"
    )
  popd
)

这将为每个 USB 驱动器处理