Groovy 方法如何多次返回？

Question

我正在尝试通过以下代码从排序地图中获取前 K 个元素：

//return top rank k elements
public static LinkedHashMap<String,Double> getTopRank(int i){
    //store top k elements
    LinkedHashMap<String, Double> result=new LinkedHashMap<>();
    int count=0;
    //use the static rankMap in the class
    rankMap.each {key,value->
        result.put(key, value);
        count++;
        if(count>=i){
            println "Time to return"
            return result;
        }
    }
    //in case the loop does not work
    return result;
}

我期望的是，当结果 Map 已经有 i 个元素的大小时，该方法将返回，给我一个 i-size 排序的地图。请注意，rankMap 按我想要的特定顺序存储元素，并且它的大小远大于我传递给方法的 int i。 我通过

调用该方法

LinkedHashMap<String,Double> content=getTopRank(outputSize);

但没想到最终内容的大小是rankMap而不是i！在控制台中，我看到了数百行 Time to return 行。 return result 行一次又一次地执行，直到到达rankMap 的末尾。 我很确定getTopRank(outputSize) 这行没有循环。然后我觉得奇怪为什么这个方法可以多次返回而没有结束。是因为我在闭包中放入了return 语句吗？ 请告知或告诉我这在 Groovy 中是如何实现的。更进一步，我怎样才能从排序的地图中只获取前 k 个元素？

Answer 1

您误解了 Groovy 的关键概念。

在到达结束之前完成each() 执行的唯一方法是抛出异常。如果您想有条件地退出循环，请使用标准循环类型，例如 for 或 while：

int count=0
def result = [:]
for( def e in rankMap ){
  count++
  result[ e.key ] = e.value
  if( i <= count ) return result
}

Answer 2

方法本身没有返回。 each 是一个接收闭包的方法。闭包有自己的返回上下文，它与调用它们的方法无关，因此循环不会中断。

我想建议从地图的entrySet 中获取一个范围并收集结果条目：

def getTopRank(int i) {
    rankMap
        .entrySet()
        .toList()[0..<i]
        .collectEntries()
}

rankMap = [
    'Beatles'        : 'The White Album',
    'Pink Floyd'     : 'The Dark Side of the Moon',
    'Rolling Stones' : 'Sticky Fingers',
    'The Doors'      : 'Morrison Hotel',
    'Bob Dylan'      : 'Bob Dylan'
]


assert getTopRank(2) == [
    'Beatles'    : 'The White Album',
    'Pink Floyd' : 'The Dark Side of the Moon']

assert getTopRank(4) == [
    'Beatles'        : 'The White Album',
    'Pink Floyd'     : 'The Dark Side of the Moon',
    'Rolling Stones' : 'Sticky Fingers',
    'The Doors'      : 'Morrison Hotel',]

Answer 3

public static LinkedHashMap<String,Double> getTopRank(int i){
    rankMap.take(i)
}

http://www.groovy-lang.org/gdk.html
http://docs.groovy-lang.org/latest/html/groovy-jdk/java/util/Map.html#take(int)