Groovy：从类方法内部动态地将属性添加到 groovy 类

Question

我有以下代码：

class MyClass {
    def myMethod() {
        variable = "I am a variable"
    }

    def propertyMissing(String name) {
        println "Missing property $name"
    }
}

MyClass myClass = new MyClass();
myClass.myProperty
myClass.myMethod();

在 myClass.myProperty，Missing property myProperty 被打印到控制台。

但是在myClass.myMethod() 中，groovy 并没有尝试去propertyMissing，而是抛出一个

groovy.lang.MissingPropertyException: No such property: variable for class: MyClass

网上有搜索显示是因为myClass.myProperty调用了getter方法，重定向到propertyMissing。

我猜想在类方法中，groovy 不会通过 getter 方法获取变量，这就是为什么不会调用 propertyMissing 的原因？

有没有办法使用动态propertyMissing 或getProperty 或类似的东西来实现我想要做的事情？

附：我不想在 myMethod 中执行 def variable = ... 或 String variable = ...。我希望myMethod 中的语法将保持为variable = ...，但在该方法之外添加任何内容都是可以接受的。

Answer 1

你可以让你的班级extend Expando (Expando is described here)

class MyClass extends Expando {
    def myMethod() {
        variable = "I am a variable"
    }

    def propertyMissing(String name) {
        println "Missing property $name"
    }
}

MyClass myClass = new MyClass()
myClass.myProperty
myClass.myMethod()
println myClass.variable

您可以通过为变量创建自己的支持映射并自己编写 get/setProperty 方法来手动实现类似的功能，即：

class MyClass {

    def myMethod() {
        variable = "I am a variable"
    }

    def propertyMissing(String name) {
        println "Missing property $name"
    }

    def backingMap = [:]

    Object getProperty( String property ) {
      if( backingMap[ property ] == null ) {
        propertyMissing( property )
      }
      else {
        backingMap[ property ]
      }
    }

    void setProperty( String property, Object value ) {
      backingMap[ property ] = value
    }
}

MyClass myClass = new MyClass()
myClass.myProperty
myClass.myMethod()
println myClass.variable

尽管您可以从 source code for Expando 中看到，这个手卷版本的检查要少得多，我会少信任它；-)