Perl OO - 创建对象列表

Question

我有一个创建 Document 对象的包：

package Document;

sub new
{
    my ($class, $id) = @_;
    my $self = {};
    bless $self, $class;
    $self = {
        _id => $id,
        _title => (),
        _words => ()
    };
    bless $self, $class;
    return $self;
    }

sub pushWord{
    my ($self, $word) = @_;
    if(exists $self->{_words}{$word}){
        $self->{_words}{$word}++;
    }else{
        $self->{_words}{$word} = 0;
    }
}

我称之为：

my @docs;

while(counter here){
    my $doc = Document->new();
    $doc->pushWord("qwe");
    $doc->pushWord("asd");
    push(@docs, $doc);
}

在第一次迭代中，第一个$doc 的哈希有两个元素。在第二次迭代中，第二个$doc 的哈希有四个元素（包括第一个元素中的两个）。但是当我使用那个实体对象（创建一个Document 的数组）时，我得到：

• 散列大小为 x 的 Document-1
• 散列大小为 x+y 的 Document-2
• 散列大小为 x+y+z 的 Document-3

为什么哈希的大小会增加？ Document-3 包含 Document-1 和 Document-2 中的所有哈希内容。这与祝福或取消定义变量有关吗？构造函数错了吗？

谢谢:D

Answer 1

你有两个主要问题

• 您对$self的初始化

  $self = {
      _id => $id,
      _title => (),
      _words => ()
  };
  

  是非常错误的，因为空括号() 不会在结构中添加任何内容。如果我在此之后转储$self，我会得到

  { _id => 1, _title => "_words" }
  

  你也祝福$self两次，但这没有问题：这更多的是表明你不明白自己在做什么。

• 不需要为第一次出现的单词初始化散列元素：Perl 会为你做这件事。此外，您应该将计数初始化为 1 而不是 0。

这是您的代码正常工作的示例。我已经使用Data::Dump 来显示三个文档对象的内容。

use strict;
use warnings;

package Document;

sub new {
    my ($class, $id) = @_;

    my $self = {
        _id => $id,
        _words => {},
    };

    bless $self, $class;
}

sub pushWord {
    my ($self, $word) = @_;

    ++$self->{_words}{$word};
}



package main;

use Data::Dump;

my $doc1 = Document->new(1);
my $doc2 = Document->new(2);
my $doc3 = Document->new(3);

$doc1->pushWord($_) for qw/ a b c /;
$doc2->pushWord($_) for qw/ d e f /;
$doc3->pushWord($_) for qw/ g h i /;

use Data::Dump;

dd $doc1;
dd $doc2;
dd $doc3;

输出

bless({ _id => 1, _words => { a => 1, b => 1, c => 1 } }, "Document")
bless({ _id => 2, _words => { d => 1, e => 1, f => 1 } }, "Document")
bless({ _id => 3, _words => { g => 2, h => 2, i => 2 } }, "Document")