如何在 XSLT 输出中保留 XML 命名空间？

Question

XSL 样式表应向 Internet Explorer 输出以下代码：

<xml:namespace prefix="vml" ns="urn:schemas-microsoft-com:vml"/>

但是当我使用任何 XML 执行以下模板时

<xsl:template match="*|node()">
    <xml:namespace prefix="vml"
                   ns="urn:schemas-microsoft-com:vml"/>
</xsl:template>

IE 抛出解析错误：样式表不包含文档元素。 同时 Firefox 在输出中删除 xml 命名空间...

那么，如何在输出中保留 xml 命名空间？

重要

一个。我使用的输出方法是 html

b.以下代码不能解决我的问题：

<xsl:template match="*|node()">
    <namespace prefix="vml"
               xmlns="http://www.w3.org/XML/1998/namespace"
               ns="urn:schemas-microsoft-com:vml"/>
</xsl:template>

Answer 1

您不能使用保留的xml 前缀。使用这样的东西：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:dummy="dummy">
<xsl:namespace-alias stylesheet-prefix="dummy" result-prefix="xml"/>
<xsl:template match="/">
    <dummy:namespace prefix="vml"
                   ns="urn:schemas-microsoft-com:vml"/>
</xsl:template>
</xsl:stylesheet>

任何输入，你都会得到这个结果：

<xml:namespace prefix="vml" ns="urn:schemas-microsoft-com:vml" />

Answer 2

如果你真的想要问题中显示的结果，这很容易实现：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes"/>

 <xsl:template match="/">
  <xml:namespace prefix="vml" ns="urn:schemas-microsoft-com:vml"/>
 </xsl:template>
</xsl:stylesheet>

当应用于任何 XML 文档（未使用）时，此转换会产生所需的结果：

<xml:namespace prefix="vml" ns="urn:schemas-microsoft-com:vml"/>

但是，在我看来，您想为给定 XML 文档的每个元素添加一个命名空间节点（如果不是这样，请通过评论告诉我，我将删除此答案）。

如果是这样，这里有一个简单有效的方法：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:vml="urn:schemas-microsoft-com:vml"
     exclude-result-prefixes="vml">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:variable name="vNamespace" select=
     "document('')/*/namespace::*[name()='vml']"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="/*">
     <xsl:copy>
       <xsl:copy-of select="$vNamespace"/>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

应用于任何文档时，例如这个：

<t>
    <a x="3">
        <b y="4"/>
    </a>
</t>

产生想要的结果：

<t xmlns:vml="urn:schemas-microsoft-com:vml">
   <a x="3">
      <b y="4"/>
   </a>
</t>

乍一看可能令人困惑，因为只有结果的顶部元素明显具有所需的命名空间节点。但是，根据定义（查看 XML Namespace spec），如果（子）树根部的元素具有给定的命名空间节点，则其所有后代元素也具有该命名空间节点。即使您将命名空间复制到每个元素，XSLT 序列化程序也会将其从除顶部元素之外的所有元素的序列化（文本）表示中剥离。

在 XSLT 2.0 中，您可以简单地使用 <xsl:namespace> 指令：

<xsl:namespace name="vml" select="urn:schemas-microsoft-com:vml"/>