创建模块时 Haskell 中的名称冲突

Question

在下面的代码中我不得不使用elem'而不是简单的elem，因为prelude已经有一个函数elem，我如何在声明Tree模块时使用elem，避免冲突？？

module Tree(Tree(..), singleton, insert, elem') where

data Tree a = Empty | Node a (Tree a) (Tree a) deriving (Show)

singleton :: a -> Tree a
singleton a = Node a Empty Empty

insert :: (Ord a) => a -> Tree a -> Tree a
insert e Empty = singleton e
insert e tree@(Node e2 left right)
  | e == e2 = tree
  | e > e2 = Node e2 left (insert e right)
  | e < e2 = Node e2 (insert e left) right

elem' :: (Ord a) => a -> Tree a -> Bool
e `elem'` Empty = False
e `elem'` (Node e2 left right)
  | e == e2 = True
  | e > e2 = e `elem'` right
  | e < e2 = e `elem'` left

Answer 1

虽然Prelude 模块默认在作用域内，但它可以被覆盖。任何不显式导入Prelude的模块在开头都有一个隐含的import Prelude；但是，如果您显式导入 Prelude，则不会添加它。因此，您可以使用hiding 导入Prelude 以外的elem：

import Prelude hiding (elem)

在您的代码上下文中，这是

module Tree(Tree(..), singleton, insert, elem) where

import Prelude hiding (elem)

data Tree a = Empty | Node a (Tree a) (Tree a) deriving (Show)

-- ...

elem :: (Ord a) => a -> Tree a -> Bool
e `elem` Empty = False
e `elem` (Node e2 left right)
  | e == e2 = True
  | e > e2 = e `elem` right
  | e < e2 = e `elem` left

如果您仍然需要引用Prelude.elem，您也可以随时添加额外的import qualified Prelude 行。

有关模块导入的更多信息，请参阅 the Haskell Wiki's nice summary of import，包括有关如何导入模块的各种选项以及一些关于（抑制）隐式 Prelude 导入的信息。

---

(当然，虽然你通常不太可能需要它，但模块的最终仲裁者是the Haskell 2010 report, Ch. 5；§5.3 是关于导入语法，§5.5 是关于名称冲突，§5.6 是关于Prelude（包括§5.6.2，“阴影前奏曲名”）。