TableLayoutPanel 没有删除控件

Question

添加工作正常

Private Sub AddColumnToTableLayout()
    Me.m_TblLyBtnHost.ColumnStyles.Add(New System.Windows.Forms.ColumnStyle(System.Windows.Forms.SizeType.Percent, (100 / m_TblLyBtnHost.ColumnCount)))
    For iColumnStyle As Integer = 0 To Me.m_TblLyBtnHost.ColumnStyles.Count - 1
        Me.m_TblLyBtnHost.ColumnStyles.Item(iColumnStyle).SizeType = SizeType.Percent
        Me.m_TblLyBtnHost.ColumnStyles.Item(iColumnStyle).Width = 100 / Me.m_TblLyBtnHost.ColumnCount
    Next

    'For iColumns As Integer = 0 To m_TblLyBtnHost.ColumnCount - 1
    '    Me.m_TblLyBtnHost.ColumnStyles.Add(New System.Windows.Forms.ColumnStyle(System.Windows.Forms.SizeType.Percent, (100 / m_TblLyBtnHost.ColumnCount)))
    'Next
    'Insert buttons for each of the new row ends
    For iRowIndex As Integer = 0 To Me.m_TblLyBtnHost.RowCount - 1
        m_btnMy = New MyButton.MyButton
        Me.SetDefaultsOnMyButtonMyButton(m_btnMy, Me.m_TblLyBtnHost.ColumnCount, iRowIndex)
        Me.m_TblLyBtnHost.Controls.Add(m_btnMy, Me.m_TblLyBtnHost.ColumnCount, iRowIndex)
    Next

End Sub

MyButton.MyButton 在 UserControl 的类中声明为

Friend WithEvents m_btnMy As MyButton.MyButton

但删除功能不是

Private Sub RemoveColumnFromTableLayout()
    For iRowIndex As Integer = 0 To Me.m_TblLyBtnHost.RowCount - 1
        Dim Ctrl As MyButton.MyButton = Me.m_TblLyBtnHost.GetControlFromPosition(iRowIndex, Me.m_TblLyBtnHost.ColumnCount - 1)
        Me.m_TblLyBtnHost.Controls.Remove(Ctrl)
    Next
    Me.m_TblLyBtnHost.ColumnStyles.RemoveAt(Me.m_TblLyBtnHost.ColumnCount - 1)
    For iColumnIndex As Integer = 0 To Me.m_TblLyBtnHost.ColumnStyles.Count - 1
        Me.m_TblLyBtnHost.ColumnStyles.Item(iColumnIndex).Width = 100 / Me.m_TblLyBtnHost.ColumnCount
    Next
End Sub

在逐步执行 RemoveColumnFromTableLayout() 时，我注意到 GetControlFromPosition 返回“Nothing”。我从一个 2x2 矩阵开始，添加一列后，我正确地拥有了一个带按钮的 2x3 矩阵。删除后，我不正确地设置了相同按钮集的 3x2 矩阵。在我意识到 GetControl 返回“Nothing”之前，我尝试在控件上使用 dispose。

感谢您的帮助。

Answer 1

一些一般说明：

• 您必须显式增加/减少 ColumnCount() 财产。
• ColumnStyle() Width 属性不需要是实际的 计算百分比。只需使所有列具有相同 价值。我使用了第一列中的任何值。接着就，随即 请记住，当列是 已删除，因为它们已经是相同的值了。
• Add() 的列值中出现“减一”错误 例行公事。
• 在 Remove() 例程中，您的 row/col 参数在 GetControlFromPosition() 电话。

这是修改后的代码：

Private Sub AddColumnToTableLayout()
    Me.m_TblLyBtnHost.ColumnCount = Me.m_TblLyBtnHost.ColumnCount + 1
    Me.m_TblLyBtnHost.ColumnStyles.Add(New System.Windows.Forms.ColumnStyle(System.Windows.Forms.SizeType.Percent, Me.m_TblLyBtnHost.ColumnStyles(0).Width))

    'Insert buttons for each of the new row ends
    For iRowIndex As Integer = 0 To Me.m_TblLyBtnHost.RowCount - 1
        m_btnMy = New MyButton.MyButton
        Me.SetDefaultsOnMyButtonMyButton(m_btnMy, Me.m_TblLyBtnHost.ColumnCount - 1, iRowIndex)
        Me.m_TblLyBtnHost.Controls.Add(m_btnMy, Me.m_TblLyBtnHost.ColumnCount - 1, iRowIndex)
    Next

End Sub

Private Sub RemoveColumnFromTableLayout()
    For iRowIndex As Integer = 0 To Me.m_TblLyBtnHost.RowCount - 1
        Me.m_TblLyBtnHost.GetControlFromPosition(Me.m_TblLyBtnHost.ColumnCount - 1, iRowIndex).Dispose()
    Next
    Me.m_TblLyBtnHost.ColumnStyles.RemoveAt(Me.m_TblLyBtnHost.ColumnCount - 1)
    Me.m_TblLyBtnHost.ColumnCount = Me.m_TblLyBtnHost.ColumnCount - 1
End Sub