在 Excel 中搜索具有相同数据的两个连续行

Question

我有一个包含大约 100 列的数据库，其中包含从 COL A 到 COL H 的相似数据。

我使用 COL J 中的公式在一列中搜索带有“-”的连续两行，并将第二行标记为双精度，如您在 J16 和 J32 上所见。 这种方法很耗时，因为我经常搜索不同的列并且每次都必须更改公式。

我想要像 N3 这样的东西。输入列 ID，当我按下回车键时，我会自动获取带有两个连续“-”的行数，并且我想增加搜索三元组和四元组。

任何帮助将不胜感激。

J2 公式：

=IF(AND(OR(F2=F1,F1="-"),F2="-"),"double","")

image here

Answer 1

在 N5 中计算双打，

=COUNTIFS(INDEX(A:H, 2, CODE(UPPER(N3))-64):INDEX(A:H, MATCH("zzz", INDEX(A:H, , CODE(UPPER(N3))-64)), CODE(UPPER(N3))-64), "-",
          INDEX(A:H, 3, CODE(UPPER(N3))-64):INDEX(A:H, MATCH("zzz", INDEX(A:H, , CODE(UPPER(N3))-64))+1, CODE(UPPER(N3))-64), "-")

这是使用的动态等价物，

=COUNTIFS(G2:G20, "-", G3:G21, "-")

在 N6 中计算三元组，

=COUNTIFS(INDEX(A:H, 2, CODE(UPPER(N3))-64):INDEX(A:H, MATCH("zzz", INDEX(A:H, , CODE(UPPER(N3))-64)), CODE(UPPER(N3))-64), "-",
          INDEX(A:H, 3, CODE(UPPER(N3))-64):INDEX(A:H, MATCH("zzz", INDEX(A:H, , CODE(UPPER(N3))-64))+1, CODE(UPPER(N3))-64), "-",
          INDEX(A:H, 4, CODE(UPPER(N3))-64):INDEX(A:H, MATCH("zzz", INDEX(A:H, , CODE(UPPER(N3))-64))+2, CODE(UPPER(N3))-64), "-")

在 N7 中计算四边形，

=COUNTIFS(INDEX(A:H, 2, CODE(UPPER(N3))-64):INDEX(A:H, MATCH("zzz", INDEX(A:H, , CODE(UPPER(N3))-64)), CODE(UPPER(N3))-64), "-",
          INDEX(A:H, 3, CODE(UPPER(N3))-64):INDEX(A:H, MATCH("zzz", INDEX(A:H, , CODE(UPPER(N3))-64))+1, CODE(UPPER(N3))-64), "-",
          INDEX(A:H, 4, CODE(UPPER(N3))-64):INDEX(A:H, MATCH("zzz", INDEX(A:H, , CODE(UPPER(N3))-64))+2, CODE(UPPER(N3))-64), "-",
          INDEX(A:H, 5, CODE(UPPER(N3))-64):INDEX(A:H, MATCH("zzz", INDEX(A:H, , CODE(UPPER(N3))-64))+3, CODE(UPPER(N3))-64), "-")

如果您需要 quints，您应该能够从中获得灵感。

Answer 2

您想在单元格 N3 中使用您的列条目。您可以使用间接函数来执行此操作。只需将单元格 J2 中的公式从更改为：

=IF(AND(OR(F2=F1,F1="-"),F2="-"),"double","")

...到这个：

=IF(AND(INDIRECT(N$3&ROW())="-",INDIRECT(N$3&ROW()-1)="-"),"double","")

你可以用同样的方法捕捉三元组和四元组，试试这个公式......它只会从第 4 行开始起作用，结果可能会让人感觉混乱，这取决于你的需要：

=IF(AND(INDIRECT(N$3&ROW()-1)="-",INDIRECT(N$3&ROW())="-"),IF(AND(INDIRECT(N$3&ROW()-2)="-",INDIRECT(N$3&ROW()-1)="-",INDIRECT(N$3&ROW())="-"),IF(AND(INDIRECT(N$3&ROW()-3)="-",INDIRECT(N$3&ROW()-2)="-",INDIRECT(N$3&ROW()-1)="-",INDIRECT(N$3&ROW())="-"),"quadruple","triple"),"double"),"")

Answer 3

参考下图有：

1. 辅助单元格 N1:N2 和 N9:N19，其内容有助于使您需要的公式更加简洁。 请参阅下面的解释和公式。

2. 包含您需要的公式的单元格，使用 SUMPRODUCT 结合某种形式的动态引用。

   1. 单元格N5:N7 给出你想要的结果，但有固定的引用。这些是
      N5: =SUMPRODUCT(($G$2:$G$21="-")*($G$3:$G$22="-"))
N6: =SUMPRODUCT(($G$2:$G$20="-")*($G$3:$G$21="-")*($G$4:$G$22="-"))
N7: =SUMPRODUCT(($G$2:$G$19="-")*($G$3:$G$20="-")*($G$4:$G$21="-")*($G$5:$G$22="-"))
      你可以掌握系统学。

   2. 单元格O5:O7 给出相同的结果，使用INDIRECT 而不是固定引用（选项#1 满足您的需要，请参阅this）。这些是
      O5: =SUMPRODUCT( (INDIRECT($N$3&$N$9):INDIRECT($N$3&($N$10-1))="-") *(INDIRECT($N$3&($N$9+1)):INDIRECT($N$3&$N$10)="-") )
O6: =SUMPRODUCT( (INDIRECT($N$3&$N$9):INDIRECT($N$3&($N$10-2))="-") *(INDIRECT($N$3&($N$9+1)):INDIRECT($N$3&($N$10-1))="-") *(INDIRECT($N$3&($N$9+2)):INDIRECT($N$3&$N$10)="-") )
      你可以掌握系统，写出单元格O7的公式。

   3. 单元格P5:P7 给出相同的结果，使用OFFSET 而不是固定引用（选项#2 满足您的需要，请参阅this、this 或this）。这些是
      P5: =SUMPRODUCT( (OFFSET($A$1,$N$12,$N$14):OFFSET($A$1,$N$13-1,$N$14)="-") *(OFFSET($A$1,$N$12+1,$N$14):OFFSET($A$1,$N$13,$N$14)="-") )
P6: =SUMPRODUCT( (OFFSET($A$1,$N$12,$N$14):OFFSET($A$1,$N$13-2,$N$14)="-") *(OFFSET($A$1,$N$12+1,$N$14):OFFSET($A$1,$N$13-1,$N$14)="-") *(OFFSET($A$1,$N$12+2,$N$14):OFFSET($A$1,$N$13,$N$14)="-") )
      你可以掌握系统，写出单元格P7的公式。

   4. 可能还有其他选项结合INDIRECT 和OFFSET（请参阅this）。 Jeeped 涵盖了使用INDEX 的选项（尽管可能不是唯一的变体）。

---

关于辅助单元格的注意事项： 我建议使用辅助单元格，这也适用于此处发布的其他答案。 当然，您可以移动这些单元格，调整相应的公式。 这里唯一重要的公式是单元格N11、=COLUMN(INDIRECT($N$3&"1"))（请参阅this 或this）。 如果您要使用INDEX，单元格N19 可能会很有用。