xslt使用子字符串从节点中提取数值

Question

我的 .xml 文件中有以下几行

<metadataObject ID="measurementFrameSet" classification="DESCRIPTION" category="DMD">
  <metadataWrap mimeType="text/xml" vocabularyName="SAFE" textInfo="Frame Set">
    <xmlData>
      <safe:frameSet>
        <safe:frame>
          <safe:footPrint srsName="http://www.opengis.net/gml/srs/epsg.xml#4326">
            <gml:coordinates>43.838726,8.275868 44.232952,11.408423 42.557594,11.770112 42.163200,8.725094</gml:coordinates>
          </safe:footPrint>
        </safe:frame>
      </safe:frameSet>
    </xmlData>
   </metadataWrap>

我可以读取整个节点

<xsl:for-each select="//metadataSection/metadataObject/metadataWrap/xmlData/safe:frameSet/safe:frame/safe:footPrint" >
    <xsl:value-of select="gml:coordinates" />
</xsl:for-each>

但我想以单独的方式仅提取“gml:coordinates”节点中的以下数值：43.838726,8.275868 42.557594,11.770112 因为在我的最终 xml 中它们将被插入到单独的字段中。

xslt 有没有办法从该节点获取子字符串？最终的 xml 应该如下所示：

<gmd:eastBoundLongitude>
    <gco:Decimal>
      43.838726
    </gco:Decimal>
</gmd:eastBoundLongitude>

Answer 1

这是提取所需坐标的一种非常简单（不是说原始）的方法：

<xsl:template match="/">
    <xsl:for-each select="//safe:footPrint" >
        <xsl:variable name="set1" select="substring-before(gml:coordinates, ' ')" />
        <xsl:variable name="set3" select="substring-before(substring-after(substring-after(gml:coordinates, ' '), ' '), ' ')" />
        <output>
            <coor1A>
                <xsl:value-of select="substring-before($set1, ',')" />
            </coor1A>
            <coor1B>
                <xsl:value-of select="substring-after($set1, ',')" />
            </coor1B>
            <coor3A>
                <xsl:value-of select="substring-before($set3, ',')" />
            </coor3A>
            <coor3B>
                <xsl:value-of select="substring-after($set3, ',')" />
            </coor3B>
        </output>
    </xsl:for-each>
</xsl:template>

当然，您的样式表必须包含 safe: 和 gml: 前缀的命名空间声明（您的 XML 输入也必须如此）。

要生成所示格式的输出，您还必须将 gmd: 和 gco: 前缀绑定到它们的命名空间 URI。

---

补充：

我正在使用 XSLT 2.0

在 XSLT 2.0 中，您可以更优雅地做到这一点：

<xsl:template match="/">
    <xsl:for-each select="//safe:footPrint" >
        <xsl:variable name="coordinates" select="tokenize(gml:coordinates, '\s|,')" />
        <output>
            <coor1A>
                <xsl:value-of select="$coordinates[1]" />
            </coor1A>
            <coor1B>
                <xsl:value-of select="$coordinates[2]" />
            </coor1B>
            <coor3A>
                <xsl:value-of select="$coordinates[5]" />
            </coor3A>
            <coor3B>
                <xsl:value-of select="$coordinates[6]" />
            </coor3B>
        </output>
    </xsl:for-each>
</xsl:template>