禁用/停用具有已发布属性的自定义组件

Question

我正在 Delphi -7 中开发一个自定义组件，我有一些 published 属性

   private
     { Private declarations }
     FFolderzip  ,Fimagezip,Ftextzip,FActivatezipComp   : Boolean;
     FMessagebo : string;
   published
    { Published declarations }
    {component Properties}
    {#1.Folder Zip}
    property ZipFolder : Boolean read FFolderzip  write FFolderzip  default False;
    {#2.Send imagezip ?}
    property ZipImage : Boolean read Fimagezip   write Fimagezip   default False;
    {#3.text files}
    property ZipText : Boolean read Ftextzip   write Ftextzip   default False;
    {#4.message}
    property ZipMessage: String read FMessagebo write FMessagebo ; 
    {#5.Activate }
    property ActivateZipper: Boolean read FActivatezipComp write  FActivatezipComp Default false;
   end;

当用户将组件放到应用程序上时，ActivateZipper 属性为用户提供了激活/启用或停用/禁用组件执行的选项。 组件创建文件 所以在构造函数中我有这个，CreateATextFileProc 将在应用程序文件夹中创建文件。所以如果我在构造函数中检查ActivateZipper 是真还是假..

我有一个constructor

     constructor TcomProj.Create(aOwner: TComponent);
     begin
       inherited;
       if ActivateZipper then CreateATextFileProc;
     end;

ActivateZipper 始终为 false，即使我在对象检查器中将其设置为 true。 如何禁止组件使用已发布的属性？

Answer 1

构造函数太早了。设计时属性值尚未流入组件。您需要等到组件的 Loaded() 方法被调用，然后才能对这些值进行操作。如果您在运行时动态创建组件，您还需要一个属性设置器，因为没有 DFM 值，因此不会调用 Loaded()。

type
  TcomProj = class(TComponent)
  private 
    ...
    procedure SetActivateZipper(Value: Boolean);
  protected
    procedure Loaded; override;
  published 
    property ActivateZipper: Boolean read FActivatezipComp write SetActivateZipper; 
  end; 

procedure TcomProj.SetActivateZipper(Value: Boolean);
begin
  if FActivatezipComp <> Value then
  begin
    FActivatezipComp := Value;
    if ActivateZipper and ((ComponentState * [csDesigning, csLoading, csLoading]) = []) then
      CreateATextFileProc; 
  end;
end;

procedure TcomProj.Loaded;
begin
  inherited;
  if ActivateZipper then CreateATextFileProc; 
end;

Answer 2

ActivateZipper 始终为 False，即使我在对象检查器中将其设置为 True。

您的激活码现在放置在构造函数中。有几件事：

• 在构造函数中，所有私有字段都被初始化为零（0、''、null、nil，取决于类型）。如果您没有另外设置，那么一旦创建组件，这些字段就会保持为零。
• 当您使用对象检查器更改属性时，组件已经创建。
• 您的代码永远不会运行。
• 如果您确实希望在创建时对其进行初始化，则还要更改默认存储说明符。

您需要的是一个属性设置器，只要通过对象检查器或代码更改属性，就会调用它：

  private
    procedure SetZipperActive(Value: Boolean);
  published
    property ZipperActive: Boolean read FZipperActive write SetZipperActive default False;

procedure TcomProj.SetZipperActive(Value: Boolean);
begin
  if FZipperActive <> Value then
  begin
    FZipperActive := Value;
    if FZipperActive then
      CreateATextFile
    else
      ...
end;

您可能会考虑在设计时关闭此功能，因为您可能只希望在运行时进行实际压缩。然后测试ComponentState中的csDesigning标志：

procedure TcomProj.SetZipperActive(Value: Boolean);
begin
  if FZipperActive <> Value then
  begin
    FZipperActive := Value;
    if csDesigning in ComponentState then
      if FZipperActive then
        CreateATextFile
      else
        ...
end;