如果文本宽度大于 TEdit 的宽度，如何显示一些指示符

Question

如果文本太长而无法在文本控件中显示，通常会在文本末尾显示省略号 (...)。例如：

This is a long text...

... 表示还有更多文字。

对于Delphi VCL TEdit控件，有没有办法显示省略号或其他方式来指示文本宽度是否大于TEdit的宽度？

Answer 1

作为简单的解决方法，您可以使用 OnEnter/OnExit 事件。当焦点离开控制时，您可以检查值是否不合适，然后用较短的标记替换它（例如“...”）。存储原始值并在用户再次开始编辑时恢复它：

type
  TForm2 = class(TForm)
    Edit1: TEdit;
    Edit2: TEdit;
    procedure Edit1Enter(Sender: TObject);
    procedure Edit1Exit(Sender: TObject);
  private
  public
    StoredValue: string;
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

procedure TForm2.Edit1Enter(Sender: TObject);
begin
  edit1.Text := StoredValue;
end;

procedure TForm2.Edit1Exit(Sender: TObject);
const
  Tail = '...';
var
  SrcTextSize,TailSize,ShortedTextSize: TSize;
  ShortedTextWidth: integer;
  DC: HDC;
  StoredObj: HGDIOBJ;
begin
  DC := GetDC(Edit1.Handle);
  try
    StoredObj := SelectObject(DC, edit1.Font.Handle);
    try
      StoredValue := edit1.Text;
      GetTextExtentPoint32(DC, PChar(StoredValue), Length(StoredValue), SrcTextSize);
      if SrcTextSize.cx>Edit1.ClientWidth then
      begin
        GetTextExtentPoint32(DC, PChar(Tail), Length(Tail), TailSize);
        GetTextExtentExPoint(DC, PChar(StoredValue), Length(StoredValue),
          Edit1.ClientWidth-TailSize.cx, @ShortedTextWidth, nil, ShortedTextSize);
        edit1.Text := Copy(StoredValue,1,ShortedTextWidth) + '...';
      end;
    finally
      SelectObject(DC, StoredObj);
    end;
  finally
    ReleaseDC(Edit1.Handle, DC);
  end;
end;