是否可以获得组件的方法值（即名称）？

Question

我需要获取一个组件的名称 (TButton)，它在设计时分配并在 Object Inspector 中看到（例如 Button1Click at Button1.OnClick 事件选项卡上的事件）。

我现在使用 TypInfo 单元通过PPropInfo 获取方法的信息，我得到OnClick 和TNotifyEvent 字符串作为值，但我没有得到Button1Click 作为字符串值。

我怎样才能得到它？

Answer 1

string := MethodName(GetMethodProp(Button1, 'OnClick').Code);

请注意，该方法需要“发布”。

Answer 2

如果属性和赋值方法都是published，你可以这样：

uses
  TypInfo;

function GetEventHandlerName(Obj: TObject; const EventName: String): String;
var
  m: TMethod;
begin
  m := GetMethodProp(Obj, EventName);
  if (m.Data <> nil) and (m.Code <> nil) then
    Result := TObject(m.Data).MethodName(m.Code)
  else
    Result := '';
end;

s := GetEventHandlerName(Button1, 'OnClick');

TypInfo 单元（GetMethodProp() 的来源）仅支持 published 属性。

您必须指定拥有方法地址的对象，因为TObject.MethodName() 会迭代对象的 VMT。并且方法必须是 published，因为 TObject.MethodName()（它的存在是为了促进 DFM 流式传输）迭代 VMT 的一部分，该部分仅填充有 published 方法的地址。

如果您使用的是 Delphi 2010 或更高版本，则可以改用 Extended RTTI，它没有 published 的限制：

uses
  Rtti;

function GetEventHandlerName(Obj: TObject; const EventName: String): String;
type
  PMethod = ^TMethod;
var
  ctx: TRttiContext;
  v: TValue;
  _type: TRttiType;
  m: TMethod;
  method: TRttiMethod;
  s: string;
begin
  Result := '';
  ctx := TRttiContext.Create;
  v := ctx.GetType(Obj.ClassType).GetProperty(EventName).GetValue(Obj);
  if (v.Kind = tkMethod) and (not v.IsEmpty) then
  begin
    // v.AsType<TMethod>() raises an EInvalidCast exception
    // and v.AsType<TNotifyEvent>() is not generic enough
    // to handle any kind of event. Basically, the Generic
    // parameter of AsType<T> must match the actual type
    // that the event is declared as.  You can use
    // TValue.GetReferenceToRawData() to get a pointer to
    // the underlying TMethod data...
    m := PMethod(v.GetReferenceToRawData())^;
    _type := ctx.GetType(TObject(m.Data).ClassType);
    for method in _type.GetMethods do
    begin
      if method.CodeAddress = m.Code then
      begin
        Result := method.Name;
        Exit;
      end;
    end;
  end;

s := GetEventHandlerName(Button1, 'OnClick');