如何检测面板是否在可视窗口中？

Question

使用 Winforms 和 vb.net VS 2012：

如果我有一个大的可滚动面板，我将一堆较小的面板放在较大的面板中。当我向上或向下滚动较大的面板时，一些较小的面板将滚动到视野之外。我的问题是，我可以在较小的面板上放置一个侦听器，以便较小的面板知道它何时滚动到视野之外？

我不能使用 .visible 属性，因为即使面板不在窗口中，它也始终设置为 true。我也知道我可以设置 .focus 属性以将其重新显示在视图中，但是当其他东西获得焦点时，它仍然会在可视窗口中失去焦点。

那么有没有我可以监听的属性或东西来检测面板何时滚动到视野之外？如果没有，我还能做些什么来检测这一点吗？

谢谢。

Answer 1

从 Panel 的 Scroll() 和 MouseWheel() 事件中，使用如下代码：

Private Sub Panel1_Scroll(sender As Object, e As ScrollEventArgs) Handles Panel1.Scroll
    CheckVisibility(sender)
End Sub

Private Sub Panel1_MouseWheel(sender As Object, e As MouseEventArgs) Handles Panel1.MouseWheel
    CheckVisibility(sender)
End Sub

Private Sub CheckVisibility(ByVal pnl As Panel)
    Dim results As New List(Of String)

    Dim pnlRectScreen As Rectangle = pnl.Parent.RectangleToScreen(pnl.Bounds)
    For Each child As Control In pnl.Controls
        Dim childRectScreen As Rectangle = pnl.RectangleToScreen(child.Bounds)
        If pnlRectScreen.IntersectsWith(childRectScreen) Then
            If pnlRectScreen.Contains(childRectScreen) Then
                results.Add(child.Name & ": Completely Visible")
            Else
                results.Add(child.Name & ": Partially Visible")
            End If
        Else
            results.Add(child.Name & ": Not Visible")
        End If
    Next

    ListBox1.DataSource = Nothing
    ListBox1.DataSource = results
End Sub

如果您只想知道它何时隐藏，则使用 Dictionary() 跟踪当前可见性，并在它变为隐藏时执行某些操作。这是一个更强大的示例：

Public Enum ControlVisibility
    Hidden
    PartialyVisible
    FullyVisible
End Enum

Private VisibiltyState As New Dictionary(Of Control, ControlVisibility)

Private Sub Form1_Shown(sender As Object, e As EventArgs) Handles Me.Shown
    Dim pnl As Panel = Panel1
    Dim pnlRectScreen As Rectangle = pnl.Parent.RectangleToScreen(pnl.Bounds)
    For Each child As Control In pnl.Controls
        Dim childRectScreen As Rectangle = Panel2.RectangleToScreen(child.Bounds)
        If pnlRectScreen.IntersectsWith(childRectScreen) Then
            If pnlRectScreen.Contains(childRectScreen) Then
                VisibiltyState.Add(child, ControlVisibility.FullyVisible)
            Else
                VisibiltyState.Add(child, ControlVisibility.PartialyVisible)
            End If
        Else
            VisibiltyState.Add(child, ControlVisibility.Hidden)
        End If
    Next
End Sub

Private Sub Panel1_Scroll(sender As Object, e As ScrollEventArgs) Handles Panel1.Scroll
    CheckVisibility(sender)
End Sub

Private Sub Panel1_MouseWheel(sender As Object, e As MouseEventArgs) Handles Panel1.MouseWheel
    CheckVisibility(sender)
End Sub

Private Sub CheckVisibility(ByVal pnl As Panel)
    Dim NewVisibility As ControlVisibility
    Dim pnlRectScreen As Rectangle = pnl.Parent.RectangleToScreen(pnl.Bounds)
    For Each child As Control In pnl.Controls
        Dim childRectScreen As Rectangle = pnl.RectangleToScreen(child.Bounds)
        If pnlRectScreen.IntersectsWith(childRectScreen) Then
            If pnlRectScreen.Contains(childRectScreen) Then
                NewVisibility = ControlVisibility.FullyVisible
            Else
                NewVisibility = ControlVisibility.PartialyVisible
            End If
        Else
            NewVisibility = ControlVisibility.Hidden
        End If

        ' has it changed?
        If VisibiltyState(child) <> NewVisibility AndAlso NewVisibility = ControlVisibility.Hidden Then
            Debug.Print(child.Name & " has become hidden: " & DateTime.Now.ToString("h:mm:ss.ffff"))
        End If

        VisibiltyState(child) = NewVisibility
    Next
End Sub