Delphi - 将线程与帧同步

Question

下午好 :-), 我有一个框架。这个Frame是我用Main Form动态创建的。

主要形式：

Interface := TInterface.Create(self);
    with handlingInterface do begin
      Parent := Form1;
      Left := 0; Top := 35;
      Width := 570; Height := 250;
    end;

在框架中我有一个线程。我从 Frame 调用这个线程。为什么我可以将 Thread 与 Frame 同步？没有：

var
Form1: TForm1;

---

我在 Frame 中调用 Thread，并且我想更改 ProgressBar 在 Frame 中的位置。我不知道，为什么我可以在 Thread 的 Synchronize 方法中访问 ProgressBar。

如果是 Form 中的 Thread 和 ProgressBar - 同步访问是 Form1.ProgressBar ...

但我在 Frame 中有 Thread 和 ProgressBar。

Answer 1

如果您只想从线程中更新进度条，则有一个更轻量级的选项。我会考虑改用 PostMessage 。无论如何，您不希望您的线程对框架的细节了解太多。

当你创建线程时，给它你框架的句柄，这样它就知道在哪里发布消息。让框架侦听包含进度位置的 Windows 消息，并更新进度条。

这是一个非常简单的示例，它将进度条从 0 增加到 100，每次增量之间有短暂的睡眠：

unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls;

const
  WM_PROGRESS_MESSAGE = WM_USER + 99;

type
  TProgressThread = class(TThread)
  private
    FWindowHandle: HWND;
  protected
    procedure Execute; override;
  public
    property WindowHandle: HWND read FWindowHandle write FWindowHandle;
  end;

  TFrame2 = class(TFrame)
    ProgressBar1: TProgressBar;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    procedure OnProgressMessage(var Msg: TMessage); message WM_PROGRESS_MESSAGE;
  public
  end;

implementation

{$R *.dfm}

{ TFrame2 }

procedure TFrame2.Button1Click(Sender: TObject);
var
  lThread: TProgressThread;
begin
  lThread := TProgressThread.Create(True);
  lThread.FreeOnTerminate := True;
  lThread.WindowHandle := Self.Handle;
  lThread.Start;
end;

procedure TFrame2.OnProgressMessage(var Msg: TMessage);
begin
  ProgressBar1.Position := Msg.WParam;
end;


{ TProgressThread }

procedure TProgressThread.Execute;
var
  lProgressCount: Integer;
begin
  inherited;

  for lProgressCount := 0 to 100 do
  begin
    PostMessage(FWindowHandle, WM_PROGRESS_MESSAGE, lProgressCount, 0);
    Sleep(15);
  end;
end;

end.

Answer 2

您可以在线程中引用进度条。

示例线程类。

unit Unit6;

interface

uses
    Classes, ComCtrls;

type
    TProgressBarThread = class(TThread)
    private
        { Private declarations }
        FProgressBar: TProgressBar;
        procedure MoveProgress;
    protected
        procedure Execute; override;
    public
        procedure SetProgressBar(ProgressBar: TProgressBar);
    end;

implementation

{ ProgressBarThread }
procedure TProgressBarThread.Execute;
begin
    { Place thread code here }
    Synchronize(MoveProgress);

end;

procedure TProgressBarThread.MoveProgress;
begin
    FProgressBar.StepIt;
end;

procedure TProgressBarThread.SetProgressBar(ProgressBar: TProgressBar);
begin
    FProgressBar := ProgressBar;
end;

end.

这样使用

var
    PBT: TProgressBarThread;
begin
    PBT := TProgressBarThread.Create(True);
    PBT.FreeOnTerminate := True;
    PBT.SetProgressBar(ProgressBar1);
    PBT.Start;
//  PBT.Resume;
end;