“已发布集 '%s' 的大小 > 4 字节”。如何修复此编译器错误？

Question

我有一组包含 138 个值的枚举值。比如：

type
  TSomething = (sOne, sTwo, sThree, ..., ..., sOnehundredAndThirtyeight);
  TSomethings = set of TSomething;

....

  TSomething = class(TPersistent)
  private
    fSomethings: TSomethings;
  published
    property Somethings: TSomethings read fSomethings write fSomethings;
  end;

编译时我收到以下错误消息：

[DCC Error] uProfilesManagement.pas(20): E2187 Size of published set 'Something' is >4 bytes

知道如何在已发布的属性中包含一组这种大小吗？

我需要在已发布部分包含此集，因为我使用 OmniXMLPersistent 将类保存到 XML 中，它只保存已发布的属性。

Answer 1

可能你需要以下技巧（我没有使用 OmniXML，无法检查）：

type
  TSomething = (sOne, sTwo, sThree, ..., sOnehundredAndThirtyeight);
  TSomethings = set of TSomething;

  TSomethingClass = class(TPersistent)
  private
    fSomethings: TSomethings;
    function GetSomethings: string;
    procedure SetSomethings(const Value: string);
  published
    property Somethings: string read GetSomethings write SetSomethings;
  end;


{ TSomethingClass }

function TSomethingClass.GetSomethings: string;
var
  thing: TSomeThing;
begin
  Result:= '';
  for thing:= Low(TSomething) to High(TSomething) do begin
    if thing in fSomethings then Result:= Result+'1'
    else Result:= Result+'0';
  end;
end;

procedure TSomethingClass.SetSomethings(const Value: string);
var
  I: Integer;
  thing: TSomeThing;
begin
  fSomethings:= [];
  for I:= 0 to length(Value) - 1 do begin
    if Value[I+1] = '1' then Include(fSomethings, TSomething(I));
  end;
end;

Answer 2

不幸的是，编译器不允许在已发布的节中包含大于 32 位的集合。集合的大小（以字节为单位）可以通过High(set) div 8 - Low(set) div 8 + 1 计算。

您可以减小集合大小，或者使用自定义类代替集合，或者您可以将枚举拆分为几个集合，每个集合的大小为 32 位。