Delphi：Indy TIdTCPClient 读取 XML

Question

我正在使用 TidTCPClient 打开一个到服务器的套接字连接。 服务器开始向我发送不同 XML 数据的音调。 但是 ReadLn 对我没有帮助，因为我不知道 xml 在哪里开始和停止。所以我决定使用 Capture。这工作正确。但正如我从文档捕获中读到的那样，它也调用了 ReadLn，这意味着它逐行读取。有时读取 30~40 行的 XML 需要 1~2 秒。所以我需要更快地阅读它。我可以使用 ReadStream 或其他任何有区别的东西吗？

我现在使用的代码：

procedure TfrmMain.ThreadRun(Sender: TIdThreadComponent);
var
  FData: TStringList;
  FMemory: TStringStream;
begin
  if Client.Connected = False then Exit;
  FData := TStringList.Create;
  Client.IOHandler.Capture(FData, '', False);
  FMemory := TStringStream.Create('',TEncoding.UTF8);
  FMemory.WriteString(FData.Text);
  CoInitialize(Nil);
  QInsert.ParamByName('XMLData').LoadFromStream(FMemory,ftBlob);
  QInsert.Execute;
  CoUninitialize;
  FMemory.Free;
  FData.Free;
end;

如您所见，我将 XML 数据插入到本地表中，这非常快，15ms ~ 60ms 取决于 XML 的大小，但获取数据真的很痛苦。

Answer 1

Capture() 在循环中调用ReadLn() 直到读取指定的终止符行（在您的示例中为空行）。

您需要知道每个 XML 文档的结束位置以及下一个文档的开始位置。如果每个文档之间没有明显的标记（空行很好，只要每个 XML 文档在空行之前都以换行符结尾，并且 XML 中不包含任何空行），那么您只剩下选项是读取第一个文档的开始标记，继续阅读直到找到相应的结束标记，然后读取下一个文档的开始标记并等待其结束标记，依此类推。

在这种情况下，您最好使用支持推送模型的 XML 解析器来处理它。您只需从套接字读取原始字节并将它们按原样推送到解析器中，让它在遇到每个顶级文档元素的开始和结束时告诉您。您可以在这两个事件之间缓冲解析器提供给您的任何数据，使用 start 事件来清除/准备缓冲区，并使用 end 事件来完成/刷新缓冲区到您的数据库。

如果您不愿意/不能使用预先存在的 XML 库，则必须编写自己的解析器。

更新：您展示的示例Capture() 将其ADelim 参数设置为''，仅当XML 文档由LF LF 或@987654327 分隔时才有效@ 序列。在这种情况下，您可以使用该分隔符作为 ReadLn() 的 ATerminator 参数，并让它一次读取 1 个完整文档，而不是使用 Capture()：

procedure TfrmMain.ThreadBeforeRun(Sender: TIdThreadComponent);
begin
  CoInitialize(Nil);
end;

procedure TfrmMain.ThreadAfterRun(Sender: TIdThreadComponent);
begin
  CoUninitialize;
end;

procedure TfrmMain.ThreadRun(Sender: TIdThreadComponent);
var
  Xml: String;
  FMemory: TStringStream;
begin
  // read until a 'CR LF CR LF' sequence is reached...
  Xml := TrimRight(Client.IOHandler.ReadLn(CR+LF+CR+LF, IndyTextEncoding_UTF8));
  // alternatively:
  // Xml := Client.IOHandler.WaitFor(CR+LF+CR+LF, True, False, IndyTextEncoding_UTF8);

  FMemory := TStringStream.Create(Xml, TEncoding.UTF8);
  try
    QInsert.ParamByName('XMLData').LoadFromStream(FMemory, ftBlob);
  finally
    FMemory.Free;
  end;

  QInsert.Execute;
end;