Delphi 根据命令行参数限制程序的单个实例

Question

我知道我以前做过，但似乎不记得是怎么做的。

我有一个程序，我已设置为使用可执行名称上的互斥锁运行单例。 单位 GlobalSU;

interface
 function IsAppRunning: Boolean;

implementation

uses
 Windows, SysUtils, Forms;

function IsAppRunning: Boolean;
var
 rtn : Cardinal;
begin
  result := False;
  CreateMutex(nil, False, PWideChar(ExtractFileName(Application.ExeName)));
  rtn := GetLastError;
  if rtn = ERROR_ALREADY_EXISTS then
   result := True;
end;

程序接受某些命令行参数，这些参数指示要对哪些数据进行操作。我不希望多个程序实例使用相同的命令行参数运行。但我确实希望能够使用不同的参数启动第二个实例。

大约一年前我这样做了，但不记得是如何做到的。我使用 DPR 中的命令行参数修改名称，然后使用互斥锁对其进行测试。

我尝试重命名 Application.ExeName 但它是只读的，所以我一定是在更改其他内容。

以下是不会编译但添加以阐明我想要做什么的代码。 顺便说一句 - “##”始终是第三个参数的前两个字符，但我使用正则表达式对其进行测试。

program EPRmailer;

uses
  Vcl.Forms,
  uMainMailer in 'uMainMailer.pas' {frmMainMailer},
  configXML in 'configXML.pas',
  GlobalSU in 'GlobalSU.pas',
  CVUtils in 'CVUtils.pas',
  QMConst in 'QMConst.pas',
  ServerAttachmentDMu in 'ServerAttachmentDMu.pas';

{$R *.res}
 var
   i : integer;
begin

  for i := 0 to ParamCount do
  if TestParam('##', ParamStr(i)) then
  Application.ExeName := Application.ExeName + '-' + ParamStr(i);

  if IsAppRunning then exit;

  Application.Initialize;
  ReportMemoryLeaksOnShutdown := DebugHook <> 0;
  Application.MainFormOnTaskbar := false;
  Application.CreateForm(TfrmMainMailer, frmMainMailer);
  frmMainMailer.RunEPR;

end.

Answer 1

您使用了错误的方法。与其重命名Application.ExeName，不如将​​可配置字符串发送到测试重复应用程序的函数。

function CreateSingleInstance(const InstanceName: string): boolean;
var
  MutexHandle: THandle;
begin
  MutexHandle := CreateMutex(nil, false, PChar(InstanceName));
  // if MutexHandle created check if already exists
  if (MutexHandle <> 0) then
    begin
      if GetLastError = ERROR_ALREADY_EXISTS then
        begin
          Result := false;
          CloseHandle(MutexHandle);
        end
      else Result := true;
    end
  else Result := false;
end;

var
  MyInstanceName: string;
begin
  Application.Initialize;
  // Initialize MyInstanceName here
  ...
  if CreateSingleInstance(MyInstanceName) then
    begin
      // Form creation 
      ...
    end
  else Application.Terminate;
end. 

函数 CreateSingleInstance 旨在在应用程序中使用一次，因为它分配的互斥锁将保持活动状态，直到应用程序终止，然后 Windows 将自动关闭互斥锁句柄。

注意：如果MyInstanceName超过MAX_PATH字符或包含反斜杠'\'字符功能将失败

CreateMutex documentation