mojolicious 脚本工作了三遍，然后崩溃

Question

以下脚本应该演示我在使用 mod_perl 在 OpenBSD5.2 上使用 Mojolicious 时遇到的问题。

脚本在 mod_perl 下作为 CGI 调用了 4 次，运行良好。脚本的额外运行导致 Mojolicious 不返回异步帖子。通常在数据到达时调用的 subs 似乎不再被调用。从命令行运行脚本工作正常，因为 perl 完全从头开始，一切都重新初始化，而 mod_perl 下不是这种情况。停止和启动 Apache 会重新初始化 mod_perl，以便脚本可以再运行 4 次。

我仅在 OpenBSDs 端口树 (2.76) 中提供的版本中使用 Mojolicious 在 OpenBSD5.2 上对此进行了测试。我认为这有点老了，但这就是 OpenBSD 附带的。

我在这里做错了吗？或者 Mojolicious 有可能有一些循环引用或导致这个问题的东西？

我对所使用的平台 (OpenBSD) 没有任何影响。所以请不要建议“使用 Linux 并安装最新的 Mojolicious 版本”。但是，如果您确定运行更高版本的 Mojolicous 会解决问题，我可能会获得安装它的许可（尽管我还不知道如何安装）。

提前致谢！

T.

这是脚本：

#!/usr/bin/perl

use diagnostics;
use warnings;
use strict;
use feature qw(switch);
use CGI qw/:param/;
use CGI qw/:url/;
use CGI::Carp qw(fatalsToBrowser warningsToBrowser);
use Mojo::IOLoop;
use Mojo::JSON;
use Mojo::UserAgent;

my ($activeconnections, $md5, $cgi);

my $ua = Mojo::UserAgent->new;
$ua->max_redirects(0)->connect_timeout(3)->request_timeout(6); # Timeout 6 seconds of which 3 may be connecting
my $delay = Mojo::IOLoop->delay();

sub online{
 my $url = "http://www.backgroundtask.eu/Systeemtaken/Search.php";
 $delay->begin;
 $activeconnections++;
 my $response_bt = $ua->post_form($url, { 'ex' => $md5 }, sub {
    my ($ua, $tx) = @_;
    my $content=$tx->res->body;
    $content =~ m/(http:\/\/www\.backgroundtask\.eu\/Systeemtaken\/taakinfo\/.*$md5\/)/;
        if ($1){
                print "getting $1\n";
                my $response_bt2 = $ua->get($1, sub {
                        $delay->end();
                        $activeconnections--;
                        print "got result, ActiveConnections: $activeconnections\n";
                        ($ua, $tx) = @_;
                        my $filename = $tx->res->dom->find('table.view')->[0]->find('tr.even')->[2]->td->[1]->all_text;
                        print "fn = " . $filename . "\n";
                }
            )
        } else {
                print "query did not return a result\n";
                $activeconnections--;
                $delay->end;
        }
 });
}

$cgi = new CGI;
print $cgi->header(-cache_control=>"no-cache, no-store, must-revalidate") . "\n";

$md5 = lc($cgi->param("md5") || ""); # read param
$md5 =~ s/[^a-f0-9]*//g if (length($md5) == 32); # custom input filter for md5 values only

if (length $md5 != 32) {
        $md5=lc($ARGV[0]);
        $md5=~ s/[^a-f0-9]*//g;
        die "invalid MD5 $md5\n" if (length $md5 ne 32);
}

online;

if ($activeconnections) {
        print "waiting..., activeconnections: $activeconnections\n" for $delay->wait;
}

print "all pending requests completed, activeconnections is " . $activeconnections . "\n";
print "script done.\n md5 was $md5\n";
exit 0;

Answer 1

好吧，我不想这么说，但这里有很多错误。最明显的是您对... for $delay->wait 的使用，这没有多大意义。此外，您正在将数字与ne 而不是!= 进行比较。不是my-ing 更深回调中的参数对于异步样式代码似乎有问题。

然后会有一些代码异味，例如对 url 进行正则表达式并不必要地关闭 $md5 变量。

最后，既然 Mojolicious 可以在 CGI 下正常运行，为什么还要使用 CGI.pm？当你这样做时，IOLoop 已经在运行，所以有些事情变得更容易了。是的，我知道您使用的是 Mojolicious 提供的系统，但是我觉得我应该提一下当前版本是 3.93 :-)

不管怎样，这里有一个例子，它去掉了很多东西，但仍然应该做和这个例子几乎一样的事情。当然，如果没有网站的有效 md5，我就无法对其进行测试（而且如果没有样本数据，我也无法摆脱 url 正则表达式）。

#!/usr/bin/perl

use Mojolicious::Lite;
use Mojo::UserAgent;

my $ua = Mojo::UserAgent->new;
$ua->max_redirects(0)->connect_timeout(3)->request_timeout(6); # Timeout 6 seconds of which 3 may be connecting

any '/' => sub {
  my $self = shift;
  $self->res->headers->cache_control("no-cache, no-store, must-revalidate");

  my $md5 = lc($self->param("md5") || ""); # read param
  $md5 =~ s/[^a-f0-9]*//g if (length($md5) == 32); # custom input filter for md5 values only

  if (length $md5 != 32) {
    $md5=lc($ARGV[0]);
    $md5=~ s/[^a-f0-9]*//g;
    die "invalid MD5 $md5\n" if (length $md5 != 32);
  }

  $self->render_later; # wait for ua

  my $url = "http://www.backgroundtask.eu/Systeemtaken/Search.php";
  $ua->post_form($url, { 'ex' => $md5 }, sub {
    my ($ua, $tx) = @_;
    my $content=$tx->res->body;
    $content =~ m{(http://www\.backgroundtask\.eu/Systeemtaken/taakinfo/.*$md5/)};
    return $self->render( text => 'Failed' ) unless $1;
    $ua->get($1, sub {
      my ($ua, $tx) = @_;
      my $filename = $tx->res->dom->find('table.view')->[0]->find('tr.even')->[2]->td->[1]->all_text;
      $self->render( text => "md5 was $md5, filename was $filename" );
    });
  });

};

app->start;