如何在 Mojolicious 模型中访问会话数据答案

【问题标题】：How to access session data in Mojolicious model如何在 Mojolicious 模型中访问会话数据
【发布时间】：2015-07-29 04:07:57
【问题描述】：

以下是 Mojolicious (6.14) 应用程序示例...对于 $_[0] 和其他不太理想的做法感到抱歉；我试着让它紧凑。

package ScopeTest;
use Mojo::Base 'Mojolicious';

sub startup {
  my $app = shift;

  $app->helper( hello    => sub { "Hello!" } );
  $app->helper( username => sub { $_[0]->session('username'); } );
  $app->helper( model    => sub { ScopeTest::Model->new( app => $_[0]->app ) } );
  $app->helper( hasPerm  => sub { $_[0]->model->hasPerm( @_ ) } );

  $app->routes->get('/alice')->to('controller#alice');
  $app->routes->get('/carol')->to('controller#carol');
  $app->routes->get('/steve')->to('controller#steve');
}

##############################
package ScopeTest::Controller;
use Mojo::Base 'Mojolicious::Controller';

sub alice { $_[0]->session( username => "alice" ); $_[0]->render_message() }
sub carol { $_[0]->session( username => "carol" ); $_[0]->render_message() }
sub steve { $_[0]->session( username => "steve" ); $_[0]->render( text =>
    sprintf "%s: %s\n", $_[0]->username, $_[0]->model->update_db ? 'Okay' : 'Fail' ) }

sub render_message { $_[0]->render( text =>
    sprintf "%s: %s\n", $_[0]->username, $_[0]->hasPerm('canLogin') ? 'Okay' : 'Fail' ) }

##############################
package ScopeTest::Model;
use Mojo::Base -base;

has 'app';

my %perms = ( alice => [ qw{ canLogin } ],
              carol => [ ],
              steve => [ qw{ canUpdateDB } ] );

sub hasPerm {
    my ( $self, $perm ) = @_;
    no warnings 'uninitialized';

    $self->app->log->debug("app->hello            = " . $self->app->hello                 );   # OKAY
    $self->app->log->debug("app->username         = " . $self->app->username              );   # FAILS
    $self->app->log->debug("session('username')   = " . $self->app->session('username')   );   # FAILS
    $self->app->log->debug("session->{'username'} = " . $self->app->session->{'username'} );   # FAILS

    my $username;   # = $self->app->username;
    return grep { $_ eq $perm } @{ $perms{$username} };
}

sub update_db {
    my ( $self, $data ) = @_;
    $self->hasPerm('canUpdateDB') or return;
    # else ...
    return 1;
}

1;

尽管像 $self->app->log->debug() 和 $self->app->dumper() 之类的东西和其他助手做正确的事情，$self->app->session 却没有。

我知道传入$app 被认为不太理想，但我预计上述方法至少可以工作......

没有一遍又一遍地传递用户名（这是一个玩具示例；真实的应用程序有几十种不同的方法，它们有时会相互调用，等等）是否有一种更简洁的方法可以从模型类中访问会话数据?

PS——在你说Model->new(username => $self->session('username')之前，这意味着知道，先验，我将需要哪些会话变量，并在构造函数和属性列表中枚举它们；我希望如果我只是通过整个$app（甚至$app->session），我可以保持未来的发展。

谢谢！

【问题讨论】：

标签： perl mojolicious

【解决方案1】：

我犯的错误是：“会话”信息与应用无关；它与控制器相关联：

$app->helper( model => sub { ScopeTest::Model->new( ctrl => $_[0] ) } );

然后：

package ScopeTest::Model;
use Mojo::Base -base;

has 'ctrl';

...
$self->ctrl->app->log->debug("username = " . $self->ctrl->username );

是的，我知道将控制器传递给模型仍然不是最佳选择，但这至少解释了为什么我之前根本无法让它工作......

【讨论】：