如何处理生成的列表框并在 VBA 中动态添加项目？

Question

我成功地动态生成了 ListBox。但我现在正在努力解决和填充那些生成的列表框。此外，我不知道如何激活这些列表框的 MultiSelect 属性。只有 ActiveX 才能做到这一点吗？

我首先在 userForm 上尝试了 ActiveX - ListBoxes。现在我切换回工作表上的“正常”列表框。 “FS”是我正在处理的工作表的名称。为了理解：我正在遍历工作表 FS 上的列并为每列创建一个 ListBox。在每个 ListBox 中，将添加相应列的条目。

For i = 1 To 10
    LastRow = FS.Cells(Rows.Count, i).End(xlUp).Row
        With FS
            Set lb = FS.Shapes.AddFormControl(xlListBox, 100, 10, 100, 100)
            lb.ControlFormat.MultiSelect = 2
            For Each cell In FS.Range(Cells(1, i), Cells(LastRow,i)).Cells
                    lb.ControlFormat.AddItem cell.Value 'This is the problematic line
            Next cell
        End With
Next i

Answer 1

我建议你这样做：

Sub test()
''''Declarations'''''''''''''''''''''''''''
Dim lb As ListBox                           '
Dim sht As Worksheet                        '
Dim rng As Range                            '
Dim cell As Range                           '
Dim i As Long                               '
'''''''''''''''''''''''''''''''''''''''''''''
Set sht = ThisWorkbook.Worksheets("Name of your worksheet")
For i = 1 To 10
    With sht
        Set rng = .Range(.Cells(1, i), .Cells(.Rows.Count, i).End(xlUp))
        Set lb = sht.ListBoxes.Add(100 * i, 10, 100, 100) 'just an indicative way to create the List boxes without them overlapping
    End With
    lb.Name = "ListBox" & i
    lb.MultiSelect = 2
    For Each cell In rng
        lb.AddItem cell.Value
    Next cell
Next i
End Sub

更新（覆盖评论）

我更新了上面的代码，将列表框命名为“ListBox1”、“ListBox2”等，而不是“List Box 1”等。

要引用其中一个列表框，您需要使用对ListBoxes 集合的引用。该集合属于列表框所在的工作表。例如，要引用“ListBoxi”，其中 i=1,2...n，您需要这样做：

sht.ListBoxes("ListBox" & i)

不幸的是，据我所知，没有.SelectedItems.Count 或类似方法可以与表单控件列表框一起使用。

考虑到这一点，您可以找到“ListBox1”的选定项目数，例如：

Dim selectedItems As Long
selectedItems = 0
Set lb = sht.ListBoxes("ListBox" & 1)
For i = 1 To lb.ListCount Step 1
    If lb.Selected(i) Then
        selectedItems = selectedItems + 1
    End If
Next i
If selectedItems = 0 Then
    MsgBox "No user selected"
End If

需要注意的几点：

1. 根据列表框是否在用户窗体上，第一项的索引从 0 到 1 不等
2. 要使用名称如Listbox1.DoSomething 来引用列表框，它必须是ActiveX 控件而不是表单控件。

Answer 2

使用 .ControlFormat.ListFillRange 代替，并将 MultiSelect 设置为 3。这样的东西应该适合你：

Sub tgr()

    Dim FS As Worksheet
    Dim lb As Shape
    Dim i As Long

    Set FS = ActiveWorkbook.Worksheets("FS")
    For i = FS.Columns("A").Column To FS.Cells(1, FS.Columns.Count).End(xlToLeft).Column
        Set lb = FS.Shapes.AddFormControl(xlListBox, (i - 1) * 100 + 10, 10, 100, 100)
        With lb
            .ControlFormat.MultiSelect = 3
            .ControlFormat.ListFillRange = FS.Range(FS.Cells(1, i), FS.Cells(FS.Rows.Count, i).End(xlUp)).Address(External:=True)
        End With
    Next i

End Sub