跨多个单元格添加组合框

Question

我需要添加组合框（ActiveX 控件）或数据验证作为下拉列表。 我有 15 个值的范围，例如高、低、中等... 已创建名为“priorityvalue”的命名范围。

我可以通过在属性中的 ListFillRange 下添加命名范围来使用组合框创建下拉列表，或者通过提供命名范围来创建数据验证列表。

但我担心的是，我需要使用上述相同值的 58 个单元格的下拉列表。为所有单元格创建组合框是一项繁琐的工作。请在这里建议我更好的选择。

数据验证列表服务于目的。但是，它使用户可以滚动浏览每个单元格上的下拉列表，这与没有输入框的组合框不同..

请推荐

Answer 1

将以下代码粘贴到 'ThisWokbook'

Private Sub Workbook_Open()

    Dim oItem As Object

    For Each oItem In Worksheets(1).OLEObjects

        If TypeName(oItem.Object) = "ComboBox" Then

            If Len(oItem.Object.Value) > 0 Then
                oItem.Object.Value = ""
            End If

        End If

    Next

    Set oItem = Nothing

End Sub

注意：对此有一些警告。上面的代码将重置工作表中的所有组合框（另外，我已将工作表设置为工作簿中的第一个工作表，您可能希望使其成为动态的）。如果您不希望它重置所有组合框而只执行通过该功能添加的组合框，则可以使用名称格式过滤您要清除的组合框

希望这会有所帮助

Answer 2

试试这个：

Sub AddComboBoxToColumns(ByVal oRange As Excel.Range)

    Dim oOLE As OLEObject
    Dim oCell As Object

    ' Loop through all the cells in the range
    For Each oCell In oRange.Cells

        ' Add ComboBox in each cell
        With oCell

            Set oOLE = .Parent.OLEObjects.Add("Forms.combobox.1")
            oOLE.Top = .Top
            oOLE.Left = .Left
            oOLE.Width = .Width
            oOLE.Height = .Height
            oOLE.Name = "ComboBox" & .Address(False, False)
            oOLE.Object.List = Array("Test1", "Test2")

        End With

    Next

    Set oOLE = Nothing

End Sub

注意：使用要添加 ComboBox 的单元格范围调用上述函数。您必须更改数组以使用您想要的值（您可以在其中键入它们或给出现有值的范围）