CSV 到 XLSX VB.NET

Question

enter image description hereenter image description here我正在学习 VB.NET，不幸的是，我的任务是做一些我不知道该怎么做的事情。

我需要创建一个基于 Windows 的快速应用程序来将 csv 文件导出到 XLSX 文件中。

是的，我知道其他帖子可能有类似的主题，但我认为这是独一无二的。

CSV 文件将有 5 个标题，`Line、Component、Picked、Placed 和 Missed。我们在第 2 列中有零件编号，它们将放在“组件”下。我从权力的角度理解，这个文件总结了总零件编号，即 0-5490045 和 JUKI 3 行，以及 Picked、Placed 和 Missed 零件的总数。我在下面提供了一个示例行。第一行是 csv 格式，第二行是输出。我不确定哪个循环最好是 FOR 循环、WHILE 循环等。我假设我需要某种循环来遍历 csv 文件中的所有数据。 我唯一的代码打开对话框并允许文件选择并尝试读入数据表。我正在尝试让这个工作，然后重组一些代码。

Imports Spire.Xls
Imports System.Windows.Forms
Imports System.Data

Public Class Form1

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

        Dim dialog As OpenFileDialog = New OpenFileDialog
        dialog.Filter="CSV document(*.csv)|*.csv"
        Dim result As DialogResult = dialog.ShowDialog
        If(result=DialogResult.OK) Then
            Dim csvFile As String = dialog.FileName
            Dim workbook As Workbook = New Workbook
            workbook.LoadFromFile(csvFile,",")
            Dim worksheet As Worksheet = workbook.Worksheets(0)
            Dim dt As DataTable=worksheet.ExportDataTable

            Me.dataGridView1.DataSource=dt
        End If
    End Sub


End Class



  JUKI 3    0-5490045 96    96  3

  Line  Component   Picked  Placed  Missed
  JUKI 3    0-5490045   99  96  3

Answer 1

我讨厌提出建议，而不是展示它是如何工作的。下面是一个使用名为Machine 的自定义对象来保存数据的示例。此类是对象的最低要求，仅用作入门的示例。它有一些字段可以在遍历列表进行计算时派上用场。您也可以在这里添加一些自定义函数/子项，以帮助完成一些涉及“机器”对象的任务。此外，您可以在此处添加一些比较功能，这些功能将使您能够对其他内容进行排序。将所有这些放在一起后，您应该会得到一个有效的 Machine 对象列表。

您可以使用此列表来帮助您继续执行任务的计算/删除重复部分。在计算数据的过程中，您可以创建Machine 对象的最终列表，您可以使用这些对象导出到带有标题的 Excel 或将其显示到 DataGridView。希望这会有所帮助。

机器类

Public Class Machine
  Private name As String
  Private partNumber As String
  Private inventoryIn As Integer
  Private inventoryOut As Integer
  Private inventoryMissing As Integer

  Public Sub New(inName As String, inPartNum As String, inInvIn As Integer, inInvOut As Integer, InInvMis As Integer)
    name = inName
    partNumber = inPartNum
    inventoryIn = inInvIn
    inventoryOut = inInvOut
    inventoryMissing = InInvMis
  End Sub

  Property GetName As String
    Get
      Return name
    End Get
    Set(value As String)
      name = value
    End Set
  End Property

  Public Overrides Function ToString() As String
    Return "Name: " + name + " #: " + partNumber + vbTab + " In:" + inventoryIn.ToString() + " Out:" + inventoryOut.ToString() + " Miss:" + inventoryMissing.ToString()
  End Function
End Class

现在您的问题是读取文件

我没有使用任何涉及 excel 的东西。由于您有一个简单的csv 文件，我们将使用它。我们还将使用上面的Machine 类。使用您的打开文件对话框，我们得到要读取的文件的名称。创建一个变量partsList 来保存读取文件时创建的Machine 对象。然后for each 循环遍历列表并将结果显示在表单上的文本框中。

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
  Dim dialog As OpenFileDialog = New OpenFileDialog
  dialog.Filter = "CSV document(*.csv)|*.csv"
  Dim result As DialogResult = dialog.ShowDialog
  If (result = DialogResult.OK) Then
    Dim csvFile As String = dialog.FileName
    Dim partsList As List(Of Machine) = ReadText(csvFile)
    For Each curMac As Machine In partsList
      TextBox1.AppendText(curMac.ToString() + Environment.NewLine)
    Next
  End If
End Sub

读取csv文件的功能

Private Function ReadText(filePath As String) As List(Of Machine)
  Dim fileReader As System.IO.StreamReader
  Dim data As List(Of Machine) = New List(Of Machine)
  fileReader = My.Computer.FileSystem.OpenTextFileReader(filePath)
  Dim curline As String = ""
  While (Not curline Is Nothing)
    curline = fileReader.ReadLine()
    '' need to check for valid data
    '' if anything is invalid simply ignore it... i.e. your bad rows
    '' keep in mind this will also ignore good rows that have a single piece of data bad
    If (StringOK(curline)) Then
      Dim newMac = GetMac(curline)
      data.Add(newMac)
    End If
  End While
  Return data
End Function

几个辅助函数来验证数据

Private Function StringOK(inString As String) As Boolean
  If (String.IsNullOrEmpty(inString)) Then
    Return False
  End If
  Dim splitArray() As String = inString.Split(",")
  Try
    If ((String.IsNullOrEmpty(splitArray(0))) Or (String.IsNullOrEmpty(splitArray(1)))) Then
      Return False
    End If
    Dim value As Integer
    If ((Not Integer.TryParse(splitArray(2), value)) Or
        (Not Integer.TryParse(splitArray(3), value)) Or
        (Not Integer.TryParse(splitArray(4), value))) Then
      Return False
    End If
    Return True
  Catch ex As Exception
    Return False
  End Try
End Function

Function GetMac(inString As String) As Machine
  Dim splitArray() As String = inString.Split(",")
  Dim value As Integer
  Dim name As String = splitArray(0)
  Dim number As String = splitArray(1)
  Integer.TryParse(splitArray(2), value)
  Dim invIn As Integer = value
  Integer.TryParse(splitArray(3), value)
  Dim invOut As Integer = value
  Integer.TryParse(splitArray(4), value)
  Dim invMis As Integer = value
  Return New Machine(name, number, invIn, invOut, invMis)
End Function

Answer 2

如果您正在尝试完成如何将数据导入数据表，下面是一种快速处理方法。这会将您的整个 csv 放入一个数据表中，然后您可以对其进行逻辑处理并创建您的 xlsx 文件。

Friend Shared Function GetExcelFile(ByVal strFileName As String, ByVal strPath As String) As DataTable

Try

    Dim dt As New DataTable

        Dim ConStr As String = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strPath & ";Extended Properties=""Text;HDR=Yes;FMT=Delimited\"""
        Dim conn As New OleDb.OleDbConnection(ConStr)
        Dim da As New OleDb.OleDbDataAdapter("Select * from " & strFileName, conn)
        da.Fill(dt)

    Return dt

Catch ex As Exception
    Return Nothing
End Try

End Function