VB.NET - 无法绑定到新的显示成员答案

【问题标题】：VB.NET - Cannot bind to the new display memberVB.NET - 无法绑定到新的显示成员
【发布时间】：2015-08-24 13:42:03
【问题描述】：

我正在尝试为允许用户选择成员的 ComboBox 分配 DataSource。运行我的应用程序时收到此错误：

无法绑定到新的显示成员。参数名称：newDisplayMember。

这是我的代码：

Private Sub StartScreen_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    'GetAllELData()
    ddlMember.DataSource = GetMemberList()
    ddlMember.DisplayMember = "DisplayName"
    ddlMember.ValueMember = "ID"


End Sub

Private Function GetMemberList() As List(Of Member)
    Dim rval = New List(Of Member)
    Dim dv As DataView = New DataView
    Dim myConnString = ConfigurationSettings.AppSettings("ConnString")

    Try
        dv = SqlHelper.ExecuteDataset(myConnString, CommandType.StoredProcedure, "spGetData").Tables(0).DefaultView
    Catch ex As Exception
        MessageBox.Show(ex.Message, "Database Error", MessageBoxButtons.OK)
    End Try

    For Each row As DataRowView In dv
        Dim mbrNum As String = row.Item("IMMBR_CD").ToString()
        Dim mbrName As String = System.Globalization.CultureInfo.CurrentCulture.TextInfo.ToTitleCase(row.Item("IMMBR_NM20").ToLower())
        Dim mbrState As String = row.Item("IMMBR_ST").ToString()

        'assigns the member data to the list of members
        rval.Add(New Member(mbrNum, mbrName, mbrState))
    Next

    Return rval
End Function

然后是我的类定义：

Public Class Member
    Public ID As String
    Public Name As String
    Public State As String
    Public DisplayName As String

    Public Sub New(ByVal i As String, ByVal n As String, ByVal s As String)
        ID = i
        Name = n
        State = s
        DisplayName = ID & " - " & Name & ", " & State
    End Sub

    Public Overrides Function ToString() As String
        Dim rval As String = ID & " - " & Name & ", " & State
        Return rval
    End Function

    Public Function GetID() As String
        Return ID
    End Function

    Public Function GetName() As String
        Return Name
    End Function

    Public Function GetState() As String
        Return State
    End Function
End Class

我不知道为什么会出现错误。一旦我在错误弹出窗口中单击“继续”，应用程序会按预期正确加载成员并且工作正常。我发现的有关该错误的所有信息都是针对将表格作为其 DataSource 而不是像我这样的自定义类传递的人，并且答案仅包含代码 sn-ps 而不是对问题原因的解释。

谁能帮我弄清楚这里出了什么问题？

非常感谢！

【问题讨论】：

至少对于 WInForms，绑定到 Fields 不会总是一样的。尝试将它们定义为属性。
解决了这个问题。谢谢！

标签： vb.net combobox dataview

【解决方案1】：

错误是由直接绑定到字段引起的。将它们定义为属性并绑定到属性解决了这个问题。

Public ReadOnly Property GetID() As String
    Get
        Return Me.ID
    End Get
End Property

Public ReadOnly Property GetName() As String
    Get
        Return Me.Name
    End Get
End Property

Public ReadOnly Property GetState() As String
    Get
        Return Me.State
    End Get
End Property

Public ReadOnly Property GetDisplayName() As String
    Get
        Return Me.DisplayName
    End Get
End Property

还有：

Private Sub StartScreen_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    'GetAllELData()
    ddlMember.DataSource = GetMemberList()
    ddlMember.DisplayMember = "GetDisplayName"
    ddlMember.ValueMember = "GetID"


End Sub

【讨论】：