将新记录粘贴到绑定的 DataGridView

Question

抱歉，如果这已经被问到了。如果是这样，我无法找到一个简单的解决方案。我试图允许用户在 DataGridView 中复制/粘贴多条记录（数据的内存副本，稍后在用户单击保存按钮时保存）并且找不到任何有效的东西。这可能是因为我对这一切有些不理解。

我使用 Visual Studio 的拖动/表格设置了一个标准的编辑表单，因此它使用 BindingSource 控件和所有其他控件。当手动在新行中逐个输入内容时它工作得很好，因此它似乎设置正确，但是当使用代码添加记录（或多个记录）时，似乎没有任何工作。

我在下面的代码中尝试了一些内容。有人可以请至少引导我朝着正确的方向前进吗？粘贴多条记录并没有那么难。

我在用户按下 Control-V 时运行此命令（剪贴板正确保存分隔字符串）：

Private Sub PasteClipboard()
    If Clipboard.ContainsText Then
        Dim sLines() As String = Clipboard.GetText.Split(vbCrLf)
        For Each sLine As String In sLines
            Dim Items() As String = sLine.Split(vbTab)

            Dim drv As DataRowView = AdjustmentsBindingSource.AddNew()
            drv.Item(1) = Items(0)
            drv.Item(2) = Items(1)
            drv.Item(3) = Items(2)
            drv.Item(4) = Items(3)
'Error on next line : Cannot add external objects to this list.
            AdjustmentsBindingSource.Add(drv)

        Next
    End If
End Sub

编辑

（绑定源绑定到数据适配器，数据适配器绑定到 mdb 文件中的表，如果这有助于理解）

我将代码的内部部分调整为：

            If (RowHasData(Items)) Then
                Dim drv As DataRowView = AdjustmentsBindingSource.AddNew()
                drv.Item("FontName") = Items(0)
                drv.Item("FontSize") = Items(1)
                drv.Item("LetterCombo") = Items(2)
                drv.Item("Adjustment") = Items(3)
                drv.Item("HorV") = Items(4)
            End If

它有点工作，但它还在 2 个新行之前添加了一个空白行。不知道这是从哪里来的，因为我什至包括了你的 RowHasData() 例程......

Answer 1

我认为“attemp3”应该可以工作，但是尚不清楚AdjustmentsBindingSource’s DataSource 是“什么”。是List<T> 还是DataTable？

如果我将 BinngSource.DataSource 设置为 DataTable，则尝试 3 似乎有效。下面是一个有效的例子。

Private Sub PasteClipboard2()
    If Clipboard.ContainsText Then
        Dim sLines() As String = Clipboard.GetText.Split(vbCrLf)
        For Each sLine As String In sLines
            Dim Items() As String = sLine.Split(vbTab)
            If (RowHasData(Items)) Then
                Dim drv As DataRowView = AdjustmentsBindingSource.AddNew()
                drv.Item("FontName") = Items(0)
                drv.Item("FontSize") = Items(1)
                drv.Item("LetterCombo") = Items(2)
                drv.Item("Adjustment") = Items(3)
                drv.Item("HorV") = Items(4)
            End If
        Next
    End If
End Sub

这似乎在我的测试中有效。我添加了一个小函数（RowHasData）来避免格式​​错误的字符串导致问题。它只是检查大小（至少 5 个项目）并检查以确保一行实际上有“一些”数据。如果一行只是空字符串，则将其忽略。

Private Function RowHasData(items As String())
    If (items.Count >= 5) Then
        For Each item In items
            If (item <> "") Then Return True
        Next
    End If
    Return False
End Function

我猜想将新行“直接”添加到BindingSource 的DataSource. 中同样容易。在下面的示例中，代码是将行“直接”添加到DataTable 中用作DataSource 到BindingSource. 我相信您可以通过简单地将新对象添加到列表中来对List<T> 做同样的事情。下面是使用BindingSource 和DataTable 的完整示例。这只是将行添加到表格的底部。

Dim gridTable1 As DataTable

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    PasteClipboard()
End Sub

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    gridTable1 = GetTable()
    FillTable(gridTable1)
    AdjustmentsBindingSource.DataSource = gridTable1
    AdjustmentsDataGridView.DataSource = AdjustmentsBindingSource
End Sub

Private Function GetTable() As DataTable
    Dim dt = New DataTable()
    dt.Columns.Add("FontName", GetType(String))
    dt.Columns.Add("FontSize", GetType(String))
    dt.Columns.Add("LetterCombo", GetType(String))
    dt.Columns.Add("Adjustment", GetType(String))
    dt.Columns.Add("HorV", GetType(String))
    Return dt
End Function

Private Sub FillTable(dt As DataTable)
    For index = 1 To 10
        dt.Rows.Add("Name_" + index.ToString(), "Size_" + index.ToString(), "Combo_" + index.ToString(), "Adjust_" + index.ToString(), "HorV_" + index.ToString())
    Next
End Sub

Private Sub PasteClipboard()
    If Clipboard.ContainsText Then
        Dim sLines() As String = Clipboard.GetText.Split(vbCrLf)
        Try
            Dim dataRow As DataRow
            For Each sLine As String In sLines
                Dim Items() As String = sLine.Split(vbTab)
                If (RowHasData(Items)) Then
                    dataRow = gridTable1.NewRow()
                    dataRow("FontName") = Items(0)
                    dataRow("FontSize") = Items(1)
                    dataRow("LetterCombo") = Items(2)
                    dataRow("Adjustment") = Items(3)
                    dataRow("HorV") = Items(4)
                    gridTable1.Rows.Add(dataRow)
                End If
            Next
        Catch ex As Exception
            MessageBox.Show("Error: " + ex.Message)
        End Try
    End If
End Sub

Private Function RowHasData(items As String())
    If (items.Count >= 5) Then
        For Each item In items
            If (item <> "") Then Return True
        Next
    End If
    Return False
End Function

希望代码有所帮助……

最后但重要的是，我只是猜测您可能没有“测试”用户可以“选择”数据的不同方式以及其他应用程序“如何”“复制”所选数据。我之前使用 WIN-OS“剪贴板”的测试有时会产生意想不到的结果。例如，如果用户使用“Ctrl”键选择多个项目以“添加”到选择，如果选择不连续，则剪贴板中会出现额外的行。我的重点是使用操作系统剪贴板是古怪的恕我直言。我建议对用户选择数据的“不同”方式进行大量测试。如果这不是问题，那么上面的代码应该可以工作。