按下刷新或全部刷新按钮后如何调用宏？

Question

最终，我想在任何人刷新工作簿后运行宏，特别是使用 Excel 中“数据”选项卡下的“刷新”按钮。

目前，我会满足于在按下刷新按钮时触发 BeforeRefresh 或 AfterRefresh QueryTable 事件。

除了微软开发中心网站上的文档，我看过的相关帖子还有：

• Excel VBA - QueryTable AfterRefresh function not being called after Refresh completes
• VBA For Excel AfterRefresh Event
• 还有其他帖子，但我缺乏发布这些帖子的声誉。

这是我所拥有的：

类模块下（qtclass）

Option Explicit

Private WithEvents qt As Excel.QueryTable

Private Sub qt_AfterRefresh(ByVal Success As Boolean)

    MsgBox "qt_AfterRefresh called sucessfully."
    If Success = True Then
        Call Module2.SlicePivTbl
        MsgBox "If called succesfully."
    End If

End Sub

Private Sub qt_BeforeRefresh(Cancel As Boolean)
    MsgBox "qt_BeforeRefresh called."
End Sub

在 ThisWorkbook 模块下

Private Sub Workbook_Open()

    Dim qtevent As qtclass
    Dim qt As QueryTable
    Set qt = ThisWorkbook.Worksheets("Data-Fund").ListObjects(1).QueryTable
    Set qtevent = New qtclass

End Sub

我也在特定工作表下尝试了第二个代码块的变体，但还没有找到任何可行的方法。我是否需要在 Worksheet 模块中调暗相关的 QueryTable？

Answer 1

您实际上还没有将查询表连接到类实例。 修改qtclass

Option Explicit

Private WithEvents qt As Excel.QueryTable
Public Property Set HookedTable(q As Excel.QueryTable)
    Set qt = q
End Property

Private Sub qt_AfterRefresh(ByVal Success As Boolean)

    MsgBox "qt_AfterRefresh called sucessfully."
    If Success = True Then
        Call Module2.SlicePivTbl
        MsgBox "If called succesfully."
    End If

End Sub

Private Sub qt_BeforeRefresh(Cancel As Boolean)
    MsgBox "qt_BeforeRefresh called."
End Sub

新的 ThisWorkbook 代码：

Dim qtevent As qtclass
Private Sub Workbook_Open()

    Set qtevent = New qtclass
    Set qtevent.HookedTable = ThisWorkbook.Worksheets("Data-Fund").ListObjects(1).QueryTable

End Sub

请注意，这是非常紧密耦合的。如果您要在类中引发事件并声明您的 qtevent 变量 WithEvents，它将更可重用。

Answer 2

来源：https://www.excelandaccess.com/create-beforeafter-query-update-events/

类： 注意：类名 = clsQuery

Option Explicit

Public WithEvents MyQuery As QueryTable

Private Sub MyQuery_AfterRefresh(ByVal Success As Boolean)
 If Success Then
  Debug.Print "After ReFresh"
 End If
End Sub

Private Sub MyQuery_BeforeRefresh(Cancel As Boolean)
 Debug.Print "Before ReFresh"
End Sub

模块：

Option Explicit
Dim colQueries As New Collection
Sub InitializeQueries()

Dim clsQ As clsQuery
Dim WS As Worksheet
Dim QT As QueryTable

For Each WS In ThisWorkbook.Worksheets
 For Each QT In WS.QueryTables
  Set clsQ = New clsQuery
  Set clsQ.MyQuery = QT
  colQueries.Add clsQ
 Next QT
Next WS

End Sub

ThisWorkbook.Event：

Private Sub Workbook_Open()
 
 Call InitializeQueries
 
End Sub