为什么在vb.net中单击按钮插入时进度条不起作用

Question

我正在创建一个插入按钮，它将记录从列表视图保存到 mysql 数据库。当用户单击插入按钮时，进度条将显示进度，直到记录被插入。问题是，进度条只有在插入任务完成后才会开始。

这对于vb.net，运行mysql数据库。过去，我尝试过使用倒计时，但它也不起作用。

'load form code
Private Sub formDevice_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Me.Refresh()
        Timer2.Enabled = False
    End Sub

'insert button
Private Sub btnInsert_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnInsert.Click
        Try
            Timer2.Enable = True
            Timer2.Start()

            Dim form As New editDevice
            form.lblName.Text = DataGridView1.CurrentRow.Cells(0).Value.ToString()

            For Each item As ListViewItem In lvLogs.Items


                Dim insert_command As New MySqlCommand("INSERT INTO fingerprint(Enroll_no,Date_time,device_name)" & _
                                               "VALUES (@Enroll_no,@Date_time,@device_name)", connection)
                insert_command.Parameters.AddWithValue("@Enroll_no", item.SubItems(1).Text)
                insert_command.Parameters.AddWithValue("@Date_time", item.SubItems(4).Text)
                insert_command.Parameters.Add("@device_name", MySqlDbType.UInt32).Value = form.lblName.Text

                connection.Open()

                If insert_command.ExecuteNonQuery() = 1 Then

                Else
                    MessageBox.Show("Error")

                End If
                connection.Close()
            Next
            MessageBox.Show("Insert done")
        Catch ex As Exception
            MessageBox.Show(ex.ToString)
        End Try

'timer code
Private Sub Timer2_Tick(sender As Object, e As EventArgs) Handles Timer2.Tick
        ProgressBar1.Increment(10)
        If ProgressBar1.Value = 100 Then
            Timer2.Stop()

        End If

    End Sub

我希望单击插入按钮时进度条会运行

Answer 1

您可以尝试在 for 循环中添加 Application.DoEvents 调用

        For Each item As ListViewItem In lvLogs.Items


            Dim insert_command As New MySqlCommand("INSERT INTO fingerprint(Enroll_no,Date_time,device_name)" & _
                                           "VALUES (@Enroll_no,@Date_time,@device_name)", connection)
            insert_command.Parameters.AddWithValue("@Enroll_no", item.SubItems(1).Text)
            insert_command.Parameters.AddWithValue("@Date_time", item.SubItems(4).Text)
            insert_command.Parameters.Add("@device_name", MySqlDbType.UInt32).Value = form.lblName.Text

            connection.Open()

            If insert_command.ExecuteNonQuery() = 1 Then

            Else
                MessageBox.Show("Error")

            End If
            connection.Close()
            Application.DoEvents()
        Next

这让您的 UI 更新（以及触发其他事件）在每个处理的项目之间进行一次。

Answer 2

暂时忘记计时器和进度条，让您的数据输入代码顺利运行。

由于您从不显示表单，因此在其上填写标签是没有用的。只需将网格单元格的值赋给参数即可。

将您的数据对象保存在本地，以便确保它们已关闭和处置。即使出现错误，Using...End Using 块也会为您执行此操作。

不要在循环中创建新的命令和参数。每次迭代中唯一变化的是参数中的 2 个值。

不要使用.AddWithValue 见http://www.dbdelta.com/addwithvalue-is-evil/ 和 https://blogs.msmvps.com/jcoehoorn/blog/2014/05/12/can-we-stop-using-addwithvalue-already/ 还有一个： https://dba.stackexchange.com/questions/195937/addwithvalue-performance-and-plan-cache-implications

我不得不猜测数据类型和大小。检查数据库的实际类型和大小。

除非您与 MySql 的连接非常缓慢，或者您的列表视图中有大量项目，否则您可能不需要进度条。如果您这样做，请参阅@jmcilhinney 评论。

Private Sub btnInsert_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnInsert.Click
    Try
        Using cn As New MySqlConnection("Your connection string")
            Using cmd As New MySqlCommand("INSERT INTO fingerprint(Enroll_no,Date_time,device_name) VALUES (@Enroll_no,@Date_time,@device_name);", cn)
                cmd.Parameters.Add("@Enroll_no", MySqlDbType.VarChar, 100)
                cmd.Parameters.Add("@Date_time", MySqlDbType.DateTime)
                cmd.Parameters.Add("@device_name", MySqlDbType.UInt32).Value = DataGridView1.CurrentRow.Cells(0).Value.ToString()
                cn.Open()
                Dim d As DateTime
                For Each item As ListViewItem In lvLogs.Items
                    DateTime.TryParse(item.SubItems(4).Text, d)
                    cmd.Parameters("@Enroll_no").Value = item.SubItems(1).Text
                    cmd.Parameters("@Date_time").Value = d
                    cmd.ExecuteNonQuery()
                Next
            End Using
        End Using
        MessageBox.Show("Insert done")
    Catch ex As Exception
        MessageBox.Show(ex.Message)
    End Try
End Sub