如何从 TGUID 获取接口类型信息？

【问题标题】：How to get interface type info from TGUID?如何从 TGUID 获取接口类型信息？
【发布时间】：2017-02-20 17:18:27
【问题描述】：

如何从 GUID 获取类型信息？

procedure MyProcedure(const InterfaceId: TGuid);
var
  MyTypeInfo: PTypeInfo;
begin
  MyTypeInfo := TypeInfo(InterfaceId);  //E2133 TYPEINFO standard function expects a type identifier
  ...
end;

【问题讨论】：

您能否使用 RTTI 枚举所有接口并检查与您的 GUID 匹配的接口
这正是你必须做的。在 D2010 和更高版本中使用扩展 RTTI 更容易，但在标准 RTTI 中必须为 done manually。

标签： delphi guid typeinfo

【解决方案1】：

您必须在 EXE 中搜索所有 RTTI。对于 Delphi 2010 及更高版本：

unit RTTI.Utilities;

interface

uses System.TypInfo;

function InterfaceTypeInfoOfGUID(const AGUID : TGUID) : PTypeInfo;

implementation

uses System.RTTI;

function InterfaceTypeInfoOfGUID(const AGUID : TGUID) : PTypeInfo;

var
   Context : TRttiContext;
   ItemType : TRttiType;

begin
   for ItemType in Context.GetTypes do
      begin
         if ItemType is TRTTIInterfaceType then
            begin
               if TRTTIInterfaceType(ItemType).GUID = AGUID then
                  exit(TRTTIInterfaceType(ItemType).Handle);
            end
      end;
   Result := nil;
end;

end.

【讨论】：