【问题标题】:Batch file looping through files in a specific date/time order批处理文件以特定日期/时间顺序循环文件
【发布时间】:2016-01-14 23:12:50
【问题描述】:

按特定日期/时间顺序循环文件

大家好,

我正在努力为我已经使用了一段时间的批处理文件编写一个小补充。首先,这是我将要处理的一些示例文件名:

output.log, output.log.1, output.log.2, ..., outlput.log.199

输入文件集可能仅包含上述文件中的 1 个或几个(始终按照显示的顺序,最新的在前,最旧的在后),或全部 200 个文件。

我想做什么

批处理文件用于对这些文件执行几项操作,例如将它们复制到新目录,或创建参数列表以将它们传递给另一个命令。一般来说,我所拥有的运行良好,它完成了我当时想要的,但是,处理潜在文件集中的所有 200 个文件非常耗时。我现在要做的是限制进程文件的数量,只提取第一个文件,比如 20 个文件,或者(如果文件少于 20 个),全部提取。

我遇到的问题是FOR 循环我使用的是按名称顺序而不是日期/时间顺序来循环文件。因此,如果我在 20 次迭代后停止,我最终会得到:

output.log, output.log.1, output.log.10, outlput.log.100, outlput.log.101, ...

我需要能够循环浏览按日期/时间顺序设置的文件(最新的优先)。我不知道日期范围是什么,或者文件是否在特定的时间间隔内,只有日志文件将始终按照第一个列表。

我的代码

setlocal EnableDelayedExpansion

Set SnapDir=C:\Snaps\
Set SupportLog=unified_support.log
Set LogDir=\var\log
Set ParsedLogDir=\var\log\parsed
set PARAMS=
set /A NumberSupportFiles=20
Set /A StartSupportCount=0

if [%1]==[] goto :eof
:loop

rem Create a Parameter list of all the Log files, Copy File then stop after a set number of interations
for %%A in ("%SnapDir%%~n1%LogDir%\%SupportLog%*") do (
    set PARAMS=!PARAMS! "%%A"
    copy %%A "%SnapDir%%~n1%ParsedLogDir%\"
    set /A StartSupportCount+=1
    if !StartSupportCount! EQU %NumberSupportFiles% goto :jump
)

:jump

pause

如前所述,这有点用,它遍历文件集中的前 20 个文件,但文件顺序是按名称而不是日期/时间。

从我目前所读到的内容来看,任何日期/时间操作似乎都需要一个精确的参考点或特定的定界,而且我看不到在循环之前对集合进行排序的方法。这可能吗?

【问题讨论】:

    标签: date batch-file for-loop


    【解决方案1】:

    您几乎完成了,您只需将for 循环替换为for /F,它会解析dir /B A:-D /O:-D 的输出,它构成按修改日期降序排列的文件列表(最新的在前) :

    @echo off
    setlocal EnableExtensions EnableDelayedExpansion
    
    Set "SnapDir=C:\Snaps\"
    Set "SupportLog=unified_support.log"
    Set "LogDir=\var\log"
    Set "ParsedLogDir=\var\log\parsed"
    set "PARAMS="
    set /A NumberSupportFiles=20
    Set /A StartSupportCount=0
    
    if "%~1"=="" goto :EOF
    :LOOP
    rem Create a Parameter list of all the Log files,
    rem Copy File then stop after a set number of interations
    for /F "eol=| delims=" %%A in ('
        dir /B /A:-D /O:-D "%SnapDir%%~n1%LogDir%\%SupportLog%*"
    ') do (
        set "PARAMS=!PARAMS! "%%~A""
        copy "%SnapDir%%~n1%LogDir%\%%~A" "%SnapDir%%~n1%ParsedLogDir%\"
        set /A StartSupportCount+=1
        if !StartSupportCount! EQU %NumberSupportFiles% goto :JUMP
    )
    :JUMP
    pause
    endlocal
    exit /B
    

    【讨论】:

    • 太棒了。我认为这在 PowerShell 中会更容易,但我需要学习 PowerShell。我需要对“FOR”循环中的变量进行更改。当您将文件列表传递到集合中时,“%%A”变量现在显示文件名,而不是完整路径。添加了一些其他变量,完成:` for /F "eol=| delims=" %%A in (' dir /B /A:-D /O:-D "%SnapDir%%~n1%LogDir%\%SupportLog %*" ') 做 ( set PARAMS=!PARAMS! "%%A" copy "%SnapDir%%~n1%LogDir%\%%A" "%SnapDir%%~n1%ParsedLogDir%\" set /A StartSupportCount+ =1 if !StartSupportCount! EQU %NumberSupportFiles% goto :jump ) `
    • 所以基本上你改变了copy 源?您也可以只声明copy "%%~fA" ...(注意~f)以获取完整路径...
    • 啊,我没有意识到你可以像这样扩展变量。很棒的提示。
    • 当您在命令提示符窗口中输入for /? 时,您可以找到所有可能的~ 修饰符(参见最后一页)...
    • 有趣的是,在这种情况下,%%A 变量的 ~f 扩展没有按预期工作。实际发生的是,它似乎扩展了工作目录的路径,而不是 FOR 循环中使用的目录。因此,实际路径是错误的。
    猜你喜欢
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 2019-08-11
    • 1970-01-01
    • 2022-10-21
    • 1970-01-01
    • 2015-02-28
    • 2023-03-23
    相关资源
    最近更新 更多