如何操纵颜色以提供实时发光效果？

Question

我正在尝试制作一个当鼠标指向它时会发光的按钮。背景中必须有一个计时器来控制这些颜色的平滑淡入淡出。它不会从一种颜色跳到另一种颜色，它会逐渐消失到下一种颜色。

现在我的问题是，当它变回正常颜色时，它不会锁定到最终颜色。事实上，它一直在从亮到暗。

这是我的一个自定义按钮，我不打算发布它的代码，但是这个代码可以通过鼠标进入/退出事件和颜色属性放置到任何东西上。

它通过设置变量FMenuDestColor 来工作。 ExtractColor 根据颜色获取 RGB 值。计时器比较当前颜色和目标颜色之间的每个 RGB 通道。然后计时器修改当前颜色以淡入下一个颜色。这些计算在一个名为 CalcColorFade 的函数中完成 - 每个通道运行 3 次。

procedure ExtractColor(const Color: TColor; var R, G, B: Byte);
begin
  R:= GetRValue(Color);
  G:= GetGValue(Color);
  B:= GetBValue(Color);
end;

function CalcColorFade(const C1, C2: Byte): Byte;
const
  RGB_MULT = 1.2;
  RGB_SENS = 5;
begin
  if C1 <> C2 then begin    
    if (C1 >= C2 - RGB_SENS) and (C1 <= C2 + RGB_SENS) then
      Result:= C2
    else
      if C1 > C2 then
        Result:= EnsureRange(Trunc(C1 / RGB_MULT), 0, 255)
      else
        Result:= EnsureRange(Trunc(C1 * RGB_MULT), 0, 255);
  end else begin
    Result:= C2;
  end;
end;

procedure TfrmMain.tmrMenuGlowTimer(Sender: TObject);
var
  R1, G1, B1: Byte;
  R2, G2, B2: Byte;
  R3, G3, B3: Byte;
begin
  if MenuButton.Color <> FMenuDestColor then begin
    ExtractColor(MenuButton.Color, R1, G1, B1);
    ExtractColor(FMenuDestColor, R2, G2, B2);
    R3:= CalcColorFade(R1, R2);
    G3:= CalcColorFade(G1, G2);
    B3:= CalcColorFade(B1, B2);
    MenuButton.Color:= RGB(R3, G3, B3);
  end;
end;

procedure TfrmMain.MenuButtonMouseEnter(Sender: TObject);
begin
  FMenuDestColor:= clBlue;
end;

procedure TfrmMain.MenuButtonMouseLeave(Sender: TObject);
begin
  FMenuDestColor:= clNavy;
end;

将鼠标指向它，它会淡出到下一个颜色。但是把鼠标移开，它就不会锁定在原来颜色的位置——它在明暗之间来回摇晃。

我假设必须有一种更简洁的方法来完成我正在做的事情，我也愿意接受这些建议。

定时器的时间间隔是70，常数是1.2，改成1.1就可以了。因此，将其更改为 1.2 的一些事情搞砸了。

Answer 1

为什么不直接切换到 HSB/HSV 模式？

然后您可以设置色调 (0-359)，并控制饱和度、亮度和 Alpha。

后三个中的每一个都为您提供滚动发光效果的选项。

Answer 2

通过将另一个常量 RGB_SENS 调整为 7 解决了问题。

所以似乎我选择RGB_MULT 越高，我就必须选择越高RGB_SENS。

首先获取控件的当前颜色，然后获取目标颜色，将这些颜色中的每一个拆分为 RGB 通道，然后对于这些通道中的每一个，它执行此函数以获取“新”RGB 值...

function DoCalc(const Curr, Dest: Byte): Byte;
const
  RGB_MULT = 1.2; //How much color change per step
  RGB_SENS = 10;  //Distance from dest +/- until "locked" into dest
begin
  if Curr <> Dest then begin
    if (Curr >= Dest - RGB_SENS) and (Curr <= Dest + RGB_SENS) then begin
      Result:= Dest; //Lock color into destination (sensitivity)
    end else begin
      if Curr > Dest then begin //Needs to go down
        Result:= EnsureRange(Trunc(Curr / RGB_MULT), 0, 255);
      end else begin            //Needs to go up
        Result:= EnsureRange(Trunc(Curr * RGB_MULT), 0, 255);
      end;
    end;
  end else begin
    Result:= Dest; //Just return the dest color, no change
  end;
end;

以前，RGB_MULT 曾经设置为1.1，效果很好。但是当我将它增加到1.2 时，我的问题就开始了。当时，RGB_SENS 被设置为5。 RGB_SENS 确定距离目标颜色多远，直到颜色应“锁定”到位。显然，1.2 导致它永远不会落在这个范围内。将RGB_SENS 扩展为7（现在是10）后，它工作正常。