Delphi XE7 BDE Alias - 在运行时设置它？

Question

我使用 Delphi XE7，我们的一个大型遗留应用程序仍然广泛使用带有 Paradox 表的 BDE。我知道 BDE 已被弃用，但我们对这个应用别无选择。

此应用当前在运行时和启动时设置 BDE 别名。它使用BDE提供的标准默认Session，并使用“TSession.AddStandardAlias”添加别名，并引用数据模块中定义的许多表。

我现在需要能够在应用程序运行后更改别名引用的文件夹路径，但发现它存在问题。基本上，它似乎可以工作，但是在更改别名后它仍然以某种方式引用以前的路径。甚至“TSession.GetAliasParams”也报告了新路径，但随后在 Bde.DBTables 中出现错误，因为它正在尝试访问不再存在的先前路径。

鉴于应用程序很大，我在以下示例项目中重现了类似的问题。如果有人愿意尝试，这是一个非常简单的应用程序，只有主窗体。您需要设置两个文件夹，并将任何 Paradox 表放到一个文件夹中，然后在“编辑”框中指定该文件夹的路径，然后按“设置别名路径”按钮，这将设置别名，然后写入按钮下方的标签，告诉您别名所指的路径。然后“查找表”按钮和编辑框使用“TSession.GetTableNames”查找是否存在表。

最简单的方法是设置两个文件夹“C:\TEMP\testBDE\path1”和“C:\TEMP\testBDE\path2”，然后在运行应用程序时将任何 Paradox 表放入 path1 “设置别名路径”按钮，然后按“查找表”按钮，它会报告该表存在。

Main form of sample app

然后改别名引用path2，为空，报指向path2，同时报表存在。然后很容易将表从path1移动到path2，然后它会报告表不存在。

任何建议将不胜感激。

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Edit1: TEdit;
    Button1: TButton;
    Button2: TButton;
    Edit2: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    procedure Button2Click(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses
  Bde.DBTables;

const
  myAlias = 'ALIAS1';

function getPathFromAlias(tempAlais : String ): String;
var
  MyStringList : TStringList;
  i, k: integer;
  tempStr, newDirectory: String;
begin
  newDirectory:='';
  MyStringList := TStringList.Create;
  try
    Session.GetAliasParams(tempAlais,MyStringList);
    { fill stringlist with driver names }
    for i := 0 to MyStringList.count-1 do
    begin
      tempStr:= uppercase(trim(MyStringList.Strings[i]));
      k := pos('PATH=', tempStr);
      if k > 0 then
      begin
        delete(tempStr,1, k+4);
        newDirectory:=tempStr;
      end;
    end;
  finally
    MyStringList.Free;
  end;
  result:=newDirectory;
end;

procedure setAliases( apath : String);
var
  MyStringList : TStringList;
begin
(*
  MyStringList := TStringList.Create;
  try
    MyStringList.Add( 'PATH='+apath);
    MyStringList.Add( 'ENABLE BCD=FALSE');
    MyStringList.Add( 'DEFAULT DRIVER=PARADOX');
    Session.ConfigMode := cmSession;
    if Session.IsAlias( myAlias) then
      Session.ModifyAlias( myAlias, MyStringList)
    else
      Session.AddStandardAlias( myAlias, apath, 'PARADOX');
    Session.ConfigMode := cmSession;
  finally
    MyStringList.Free;
  end;
*)
  Session.ConfigMode := cmSession;
  if Session.IsAlias( myAlias) then
    Session.DeleteAlias( myAlias);
  Session.AddStandardAlias( myAlias, apath, 'PARADOX');
  Session.ConfigMode := cmSession;

end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  setAliases( Edit1.Text);
  Label1.Caption := getPathFromAlias( myAlias);
end;

function TableExists(const aDataBaseName, aTableName:string): Boolean;
var
  TableNames: TStringList;
begin

  TableNames:=TStringList.Create;
  try
    Session.GetTableNames(aDatabaseName,'',True,False,TableNames);
    Result:=(TableNames.IndexOf(aTableName)<>-1);
  finally
    TableNames.Free;
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  temps : String;
  myTable : TTable;
begin

  if TableExists( myAlias, Edit2.Text) then
    Label2.Caption := 'Exists'
  else
    Label2.Caption := 'Not found'
end;

end.

Answer 1

您需要在更改别名属性之前关闭会话，然后再次打开：

procedure TForm1.Button1Click(Sender: TObject);
begin
  Session.Close;

  setAliases( Edit1.Text);
  Label1.Caption := getPathFromAlias( myAlias);

  Session.Open;
end;

问题不在于无法识别路径更改，而是如果对正在使用的别名进行此类更改，则无法识别此类更改，正如您的测试程序中的此场景所示：

1. 单击按钮 1：路径已更改
2. 点击了按钮 2：未找到表格
3. 在编辑 1 中更改路径以引用原始别名路径
4. 使用按钮 1 重置路径
5. 点击了按钮 2：仍未找到表格

即如果您要做的第一件事是更改路径，那么别名确实反映了更改后的路径。问题是，一旦您使用了别名，对路径的更改不会随后反映。

通过关闭会话并重新打开它，您可以确保别名已正确“重置”。

在您的实际应用程序中，这可能会导致连锁反应，即在关闭并重新打开会话后需要重新打开数据库连接，尽管这是我的猜测。

替代方法

作为关闭会话以在运行时修改别名的替代方法，另一种方法可能是添加具有所需属性的新别名并将数据库连接重定向到该备用别名。

这显然也需要断开并重新连接重定向到此备用别名的所有数据库和查询。