VBA 1004 循环执行宏时出错

Question

谁能告诉我为什么我会在以下代码中收到 1004 错误？

如果不清楚，我正在尝试循环所有不是我命名工作表的工作表，并尝试选择特定范围并将其复制并粘贴到已编译的“定量工作表”

Dim ws As Worksheet
Dim x As Integer 
Dim y As Integer
Dim a As Integer
Dim b As Integer
Set ws = Worksheets("Quant Sheet")
x = 1
y = 3
a = 3
b = 2

Worksheets("Quant Sheet").Activate
For Each ws In ActiveWorkbook.Worksheets
If (ws.Name <> "Quant Sheet") Then

   ws.Range("A3").Select
   Selection.Copy
   Sheets("Quant Sheet").Select
   Cells(y, 1).Select
   ActiveSheet.Paste
   y = y + 1


End If

Next ws

Answer 1

您将WS 设置为Worksheets("Quant Sheet")，然后在循环中使用相同的变量ws。这可能是导致问题的原因。

试试这个：

Dim ws As Worksheet, mainWS As Worksheet
Dim x As Integer, y As Integer, a As Integer, b As Integer
Set mainWS = Worksheets("Quant Sheet")
x = 1
y = 3
a = 3
b = 2

For Each ws In ActiveWorkbook.Worksheets
If (ws.Name <> "Quant Sheet") Then
   ws.Range("A3").Copy Destination:=mainWS.Cells(y, 1)
   y = y + 1
End If

Next ws

主要是，您想avoid using .Select/.Activate 以确保您更直接地处理数据。

编辑：仅供参考，您可以通过不使用 y=y+1 之类的东西，而是使用偏移量或 lastRow 变量来进一步使其更具动态性，但这是个人喜好，因为它会完成同样的事情。 （我还假设 x、a 和 b 变量在您的宏中的其他地方使用...

Answer 2

As was already stated，你不能在工作表上的一个单元格上.Select你没有首先调用.Activate - 这会解决问题，但会让你变得脆弱和缓慢.Select 和 .Activate 到处打电话。相反，使用For Each 循环迭代Worksheets 集合，这样每次迭代都会得到一个Worksheet 对象：

Sub test()
    Dim quantSheet As Worksheet, tempSheet as Worksheet
    Dim i As Integer

    Set quantSheet = ThisWorkbook.Worksheets("Quant Sheet")
    i = 3

    For Each tempSheet In ThisWorkbook.Worksheets
        If tempSheet.Name <> quantSheet.Name Then
            quantSheet.Cells(i, 1).Value = tempSheet.Range("A3").Value
            i = i + 1
        End If
    Next tempSheet
End Sub

---

除了已经提供的好的答案和 cmets，您还可以大量整理代码。

• 缩进是键。只需坚持简单的缩进即可避免大量错误
• 删除所有未使用的变量（除非您稍后使用它们并且没有向我们展示！）
• 不要复制和粘贴，而是直接使用.Value 设置您的值。更快更好
• 如前所述，尽可能避免使用Select 和Activate。这包括ActiveSheet 和ActiveWorkbook
• 给你的变量起一个好的、有意义的名字，你的代码读起来就像一本极客的 VBA 小说。这样您就可以随时知道发生了什么。

将您的工作代码发布到 Code Review Stack Exchange 以进行全面的同行评审。