Excel：如何按照模式连接单元格？ （单元格不在同一行！）

Question

我有以下excel：

预期结果：

我尝试过power query，excel函数，但我无法得到我需要的结果。

您认为没有 vba 是否有可能实现这一目标？

谢谢！

Answer 1

编辑 2：根据您评论中的文件，我重构了公式以使用空格

基于此单元格布局：

使用这个公式：

=TEXTJOIN("-",TRUE,
    IFERROR(INDEX(M$3:M3,MAX((M$3:M3<>"")*(ROW(M$3:M3)))-ROW(M$3)+1),""),
    IFERROR(IF(MAX((N$3:N3<>"")*(ROW(N$3:N3)))-ROW(N$3)+1<MAX((M$3:M3<>"")*(ROW(M$3:M3)))-ROW(M$3)+1,"",INDEX(N$3:N3,MAX((N$3:N3<>"")*(ROW(N$3:N3)))-ROW(N$3)+1)),""),
    IFERROR(IF(OR(MAX((O$3:O3<>"")*(ROW(O$3:O3)))-ROW(O$3)+1<MAX((M$3:M3<>"")*(ROW(M$3:M3)))-ROW(M$3)+1,MAX((O$3:O3<>"")*(ROW(O$3:O3)))-ROW(O$3)+1<MAX((N$3:N3<>"")*(ROW(N$3:N3)))-ROW(N$3)+1),"",INDEX(O$3:O3,MAX((O$3:O3<>"")*(ROW(O$3:O3)))-ROW(O$3)+1)),""),
    IF(P3<>"",IFNA(INDEX(P$3:P3,MAX((P$3:P3<>"")*(ROW(P$3:P3)))-ROW(P$3)+1),""),""))

编辑 3：如果你有它，你可以使用 LET 函数来简化它

=LET(
    a,MAX((M$3:M3<>"")*(ROW(M$3:M3)))-ROW(M$3)+1,
    b,MAX((N$3:N3<>"")*(ROW(N$3:N3)))-ROW(N$3)+1,
    c,MAX((O$3:O3<>"")*(ROW(O$3:O3)))-ROW(O$3)+1,
    d,MAX((P$3:P3<>"")*(ROW(P$3:P3)))-ROW(P$3)+1,

    TEXTJOIN("-",TRUE,
    IFERROR(INDEX(M$3:M3,a),""),
    IFERROR(IF(b<a,"",INDEX(N$3:N3,b)),""),
    IFERROR(IF(OR(c<a,c<b),"",INDEX(O$3:O3,c)),""),
    IF(P3<>"",IFNA(INDEX(P$3:P3,d),""),"")))

让我知道它是否适合你！

Answer 2

如果您可以更改代码列，以便 lvl2、lvl3、lvl4 和 lvl5 在 lvl1 具有值时成为句点（类似于图像），那么这在 powerquery 中是微不足道的

在 N3 中执行此操作的新版本公式类似于：

=IF(M3="",IF(ISBLANK(B3),"",_xlfn.XLOOKUP(B:B,lvl2_code[item description],lvl2_code[final code])),".")

将数据加载到powerquery中，数据...来自表/范围...

点击选择所有的lvl列，右键，填充...向下...

添加列...自定义列...用公式连接所有：

=[lvl1]&"-"&[lvl2]&"-"&[lvl3]&"-"&[lvl4]&"-"&[lvl5]

右键单击新列，替换值，然后将 -. 替换为 null

文件 .. 关闭并加载 ... 完成

let Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
#"Filled Down" = Table.FillDown(Source,{"lvl1", "lvl2", "lvl3", "lvl4", "lvl5"}),
#"Added Custom" = Table.AddColumn(#"Filled Down", "final_code", each [lvl1]&"-"&[lvl2]&"-"&[lvl3]&"-"&[lvl4]&"-"&[lvl5]),
#"Replaced Value" = Table.ReplaceValue(#"Added Custom","-.","",Replacer.ReplaceText,{"final_code"})
in  #"Replaced Value"

Answer 3

另一种解决方案

算法是

If first column is not empty, then take value in first column
Else
    Truncate existing final code to the length corresponding to the previous column
    Append value from the current column.

公式是

=IF(M3<>"",M3,
     LEFT(S2,FIND("|",SUBSTITUTE(S2&"-","-","|",MATCH("*",M3:Q3,0)-1))-1)
       &"-"&INDEX(M3:Q3,MATCH("*",M3:Q3,0))
  )

以下是针对未占用单元格包含空字符串而不是空白的情况的修改公式：

=IF(M3<>"",M3,
     LEFT(S2&"-",FIND("|",SUBSTITUTE(S2&"-","-","|",INDEX(MATCH(TRUE,M3:Q3<>"",0),1)-1)))
       &INDEX(M3:Q3,INDEX(MATCH(TRUE,M3:Q3<>"",0),1))
)

Match 函数周围的索引包装可以省略，但必须使用 CtrlShiftEnter 将公式输入数组