为什么输入框变量在循环的第一次迭代后切换为 null？

Question

我编写了一些简单的 VBA 代码来更新 Excel 文档中许多时间序列图表的 x 轴。

我遇到的问题是，在循环的第一次迭代之后，start_date 和 end_date 变量变为“”。我不确定为什么变量会消失。该宏确实适用于第一个图表，但之后由于变量问题而崩溃。

这是我的代码：

Sub xaxis_reset()

Dim start_date As Variant
Dim end_date As Variant
Dim ws As Integer
Dim obj As Integer

start_date = InputBox("Start Date")
end_date = InputBox("End Date")
ws = ActiveWorkbook.Worksheets.Count - 2

         For w = 1 To ws
            obj = Worksheets(w).ChartObjects.Count
                For Z = 1 To obj
                    Worksheets(w).ChartObjects(Z).Activate
                         With ActiveChart
                              .Axes(xlCategory).MinimumScale = start_date
                              .Axes(xlCategory).MaximumScale = end_date
                         End With

                Next Z
         Next w

End Sub

谢谢

Answer 1

除了声明所有变量（w、z）之外，您还必须聪明地了解如何将值传递给轴限制。您的输入框以字符串形式提供日期。 start_date 和 end_date 的值不会变成 ""，但由于某种原因，字符串仅在第一次通过循环时才被正确解释。而且由于某种原因，将字符串传递给图表轴会使 Excel 变得非常不稳定。

在下面的代码中，我使用DateValue() 将这些转换为实际日期，并将它们传递到图表中。

Sub xaxis_reset()
  Dim start_date As Variant
  Dim end_date As Variant
  Dim w As Long, ws As Long
  Dim z As Long, obj As Long

  start_date = InputBox("Start Date")
  end_date = InputBox("End Date")
  ws = ActiveWorkbook.Worksheets.Count - 2

  For w = 1 To ws
    obj = Worksheets(w).ChartObjects.Count
    For z = 1 To obj
      Worksheets(w).ChartObjects(z).Activate
      With ActiveChart
        .Axes(xlCategory).MinimumScale = DateValue(start_date)
        .Axes(xlCategory).MaximumScale = DateValue(end_date)
      End With
    Next z
  Next w
End Sub

Answer 2

我对您的代码进行了一些调整（见下文），这似乎是 Excel 如何设置属性的错误（并非总是如此，但经常修改用于将它们设置为其他值的变量）。一种解决方法（在下面的代码中使用）是使用缓冲区变量。

Sub xaxis_reset()

    Dim start_date As Variant, start_buffer As Variant
    Dim end_date As Variant, end_buffer As Variant
    Dim w As Integer
    Dim obj As ChartObject

    While Not IsDate(start_date): start_date = InputBox("Start Date"): Wend
    While Not IsDate(end_date): end_date = InputBox("End Date"): Wend

    On Error Resume Next
    For w = 1 To ActiveWorkbook.Worksheets.Count - 2
        For Each obj In ActiveWorkbook.Worksheets(w).ChartObjects
            start_buffer = start_date: end_buffer = end_date
            Debug.Print w, start_date, end_date, start_buffer, end_buffer, (start_date = start_buffer), (end_date = end_buffer)
            obj.Chart.Axes(xlCategory).MinimumScale = start_buffer
            Debug.Print w, start_date, end_date, start_buffer, end_buffer, (start_date = start_buffer), (end_date = end_buffer)
            obj.Chart.Axes(xlCategory).MaximumScale = end_buffer
            Debug.Print w, start_date, end_date, start_buffer, end_buffer, (start_date = start_buffer), (end_date = end_buffer)
        Next obj
        Set obj = Nothing
    Next w
End Sub