未知长度的字符返回函数

Question

如何使用初始结果未知长度的字符函数？

trim() 函数，据我所知，表明可以不指定返回字符串的长度。

例如：

write (*,*) trim(str)

将只返回字符串的一部分，没有尾随空格。

这个函数在调用之前不知道返回字符串的长度。

或者trim()函数有限制？

更多变种是找到trim()函数的原始代码。

我找到了 (Returning character string of unknown length in fortran)，但这不是我问题的答案。

可以肯定的是，我想写一个函数，它按整数返回字符串。

类似这样的：

function strByInt(myInt)
...
write (strByInt,fmt) myInt; return
end function strByInt

somewhere else:

write (*,*) strByInt(50) ! will write '50'

Answer 1

您引用的那个问题部分回答了它。它提到了具有延迟长度的可分配字符。请参阅下面我经常使用的实现：

  function strByInt(i) result(res)
    character(:),allocatable :: res
    integer,intent(in) :: i
    character(range(i)+2) :: tmp
    write(tmp,'(i0)') i
    res = trim(tmp)
  end function

结果变量在最后一行的赋值中分配以适应答案。

trim 函数是一个不同的野兽，作为一个内在函数，它不必在 Fortran 中编程并且可以遵循不同的规则。它只是返回它需要返回的东西。但它可以很容易地像上面那样实现。

Answer 2

Fortran2003 具有可变字符长度功能。这是一个示例代码。 该程序输出“哔！哔！”字符串。

module m_test
  implicit none
contains
  function say2(text)
    character(len = *), intent(in) :: text
    character(len = :), allocatable :: say2
    say2 = trim(text) // trim(text)
    return
  end function say2
end module m_test

program String
  use m_test
  implicit none
  print *, say2('Beep!   ')
  stop
end program String

下面一行声明了变长字符变量。

字符（len = :)，可分配的 :: say2

您可能需要在 Intel Fortran 中使用“/standard-semantics”或“启用 F2003 语义”。