【问题标题】:XSL If FunctionXSL If 函数
【发布时间】:2013-01-13 14:40:09
【问题描述】:

我有以下 XML 文档和 XSL 样式表,我的任务是将 XSL 中的 CSS 应用到样式表,并在测试结果为 FAIL 时应用它。我似乎不知道该怎么做,我尝试了 xsl:if 但似乎无法改变它。有什么想法吗?

代码如下:

XML 文件:

<?xml version="1.0"?>
<?xml-stylesheet type="text/xsl" href="results.xsl"?>
<request xmlns:xsi="httyp://www.w3.org/2001/XMLSchema-instance"
xsi:noNamespaceSchemaLocation="results.xsd">
<authentication password="turkey" partnerid="exam" />

<method name="ListUserTestResults">
    <parameters>
        <user_id>42511</user_id>
        <transcript>4234232</transcript>
        <test_id>231</test_id>
        <test_name>ASP 3.0 Test</test_name>
        <percentage>75</percentage>
        <test_result>PASS</test_result>
        <time>2006-04-19T14:05:11Z</time>
    </parameters>

    <parameters>
        <user_id>42511</user_id>
        <transcript>2356545</transcript>
        <test_id>12</test_id>
        <test_name>PHP 5.0 Test</test_name>
        <percentage>35</percentage>
        <test_result>FAIL</test_result>
        <time>2006-05-17T10:19:45Z</time>
    </parameters>
    </method>
 </request>

还有 XSL 样式表:

<?xml version="1.0"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="html" version="4.0.1"/>

<xsl:template match="/">

<style type="text/css">
    .FAIL {color:red;}
</style>

<h1>Results from tests:</h1>

<xsl:for-each select="request/method/parameters">
    <h2>
        <xsl:number count="parameters" />
        User <xsl:value-of select="user_id"/>
    </h2>

    <h3>
        <xsl:value-of select="test_name"/>
        (<xsl:value-of select="test_id"/>)
    </h3>

    <dl>
        <dt>Transcript</dt>
        <dd><xsl:value-of select="transcript"/></dd>
        <dt>Percentage</dt>
        <dd><xsl:value-of select="percentage"/>
        <xsl:if
        (<xsl:value-of select="test_result"/>)
        </dd>
        <dt>Date/Time of test</dt>
        <dd><xsl:value-of select="time"/></dd>
    </dl>
        </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>   

在浏览器中读取时,需要将 test_result 元素从黑色文本更改为 CSS 定义的红色。我只是不知道该怎么做。

【问题讨论】:

    标签: xml xslt if-statement


    【解决方案1】:

    这是一个完整的转换:

    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>
    
     <xsl:template match="/*">
        <style type="text/css">
            .FAIL {color:red;}
        </style>
        <h1>Results from tests:</h1>
    
        <xsl:apply-templates/>
     </xsl:template>
    
     <xsl:template match="parameters">
        <h2>
            <xsl:number count="parameters" />
            User <xsl:value-of select="user_id"/>
        </h2>
    
        <h3>
            <xsl:value-of select="test_name"/>
            (<xsl:value-of select="test_id"/>)
        </h3>
    
        <dl>
            <dt>Transcript</dt>
            <dd><xsl:value-of select="transcript"/></dd>
            <dt>Percentage</dt>
            <dd>
              <xsl:value-of select="percentage"/>
            </dd>
            <dt>Result</dt>
              <dd>
                  <xsl:if test="test_result = 'FAIL'">
                   <xsl:attribute name="class">FAIL</xsl:attribute>
                  </xsl:if>
                  (<xsl:value-of select="test_result"/>)
              </dd>
            <dt>Date/Time of test</dt>
            <dd><xsl:value-of select="time"/></dd>
        </dl>
     </xsl:template>
    </xsl:stylesheet>
    

    当此转换应用于提供的 XML 文档时:

    <request xmlns:xsi="httyp://www.w3.org/2001/XMLSchema-instance"
    xsi:noNamespaceSchemaLocation="results.xsd">
    <authentication password="turkey" partnerid="exam" />
    
    <method name="ListUserTestResults">
        <parameters>
            <user_id>42511</user_id>
            <transcript>4234232</transcript>
            <test_id>231</test_id>
            <test_name>ASP 3.0 Test</test_name>
            <percentage>75</percentage>
            <test_result>PASS</test_result>
            <time>2006-04-19T14:05:11Z</time>
        </parameters>
    
        <parameters>
            <user_id>42511</user_id>
            <transcript>2356545</transcript>
            <test_id>12</test_id>
            <test_name>PHP 5.0 Test</test_name>
            <percentage>35</percentage>
            <test_result>FAIL</test_result>
            <time>2006-05-17T10:19:45Z</time>
        </parameters>
        </method>
     </request>
    

    产生了想要的正确结果:

    <style type="text/css">
            .FAIL {color:red;}
        </style>
    <h1>Results from tests:</h1>
    <h2>1
            User 42511</h2>
    <h3>ASP 3.0 Test
            (231)
        </h3>
    <dl>
       <dt>Transcript</dt>
       <dd>4234232</dd>
       <dt>Percentage</dt>
       <dd>75</dd>
       <dt>Result</dt>
       <dd>
                  (PASS)
              </dd>
       <dt>Date/Time of test</dt>
       <dd>2006-04-19T14:05:11Z</dd>
    </dl>
    <h2>2
            User 42511</h2>
    <h3>PHP 5.0 Test
            (12)
        </h3>
    <dl>
       <dt>Transcript</dt>
       <dd>2356545</dd>
       <dt>Percentage</dt>
       <dd>35</dd>
       <dt>Result</dt>
       <dd class="FAIL">
                  (FAIL)
              </dd>
       <dt>Date/Time of test</dt>
       <dd>2006-05-17T10:19:45Z</dd>
    </dl>
    

    解释:

    正确使用xsl:if和xsl:attribute。

    【讨论】:

      【解决方案2】:

      这里需要&lt;xsl:when&gt; 进行条件检查

          <dl>
              <dt>Transcript</dt>
              <dd><xsl:value-of select="transcript"/></dd>
              <dt>Percentage</dt>
              <dd><xsl:value-of select="percentage"/>
                <xsl:choose>
                    <xsl:when test="test_result = 'PASS'">
                          <dd><xsl:value-of select="test_result"/></dd>
                    </xsl:when>
                    <xsl:otherwise>
                      <dd style="color: red"><xsl:value-of select="test_result"/></dd>
                    </xsl:otherwise>
                </xsl:choose>
              </dd>
              <dt>Date/Time of test</dt>
              <dd><xsl:value-of select="time"/></dd>
          </dl>
      

      【讨论】:

      • 这里不需要&lt;xsl:when&gt;。一个&lt;xsl:if&gt; 围绕一个&lt;xsl:attribute&gt; 就可以了。
      • @JLRishe 据我所知。但希望没有错。
      猜你喜欢
      • 2011-11-06
      • 2011-11-28
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 2014-12-13
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      相关资源
      最近更新 更多