在循环中的循环中使用计数器 = excel vba 中的问题

Question

您好，感谢您的帮助。

我在 excel 方面完全是个菜鸟，但由于我的研究需要，我一直在自学
我通过从 youtube 频道 ExcelVbaIsFun 改编它创建了这个基本代码

Sub ZipCodeSum2()

Dim dbsheet As Worksheet
Set dbsheet = ThisWorkbook.Sheets("Sheet1")
lr = dbsheet.Cells(Rows.Count, 1).End(xlUp).Row
SelRow = Selection.Row
'zip code
zip = dbsheet.Cells(SelRow, 2)

For i = 2 To lr 'change lr to 3 for testing purposes
Cells(i, 3).Select

 For x = 2 To lr 'change lr to 10 for testing purposes
    If dbsheet.Cells(x, 2) = zip Then
        counter = counter + dbsheet.Cells(x, 1)
    ActiveCell = counter
    End If

 Next x

Next i

End Sub

问题在于，对于第一个“i”，“外循环”运行良好，并且 sum 函数运行良好。但是，在下一个“i”中，它会添加第一个“i”和的结果，然后也将第二个“i”和添加到其中。因此，如果邮政编码相同，则基本上会导致第二个“i”是我想要的结果的两倍。

任何帮助将不胜感激！谢谢！

sample of my worksheet

Answer 1

如果您希望在执行内部循环之前重置counter，请在进入该循环之前对其进行初始化：

Sub ZipCodeSum2()
    Dim dbsheet As Worksheet
    Dim lr As Long
    Dim SelRow As Long
    Dim zip As String
    Dim i As Long
    Dim counter As Currency
    Dim x As Long

    Set dbsheet = ThisWorkbook.Sheets("Sheet1")
    lr = dbsheet.Cells(dbsheet.Rows.Count, 1).End(xlUp).Row

    For i = 2 To lr 'change lr to 3 for testing purposes
        'zip should be set inside the "For i" loop
        zip = dbsheet.Cells(i, "B").Value
        counter = 0
        For x = 2 To lr 'change lr to 10 for testing purposes
            If dbsheet.Cells(x, "B").Value = zip Then
                counter = counter + dbsheet.Cells(x, "A").Value
            End If
        Next 
        dbsheet.Cells(i, "C").Value = counter
    Next i
End Sub

---

但这可以简化为：

Sub ZipCodeSum2()
    With ThisWorkbook.Sheets("Sheet1")
        With .Range("C2:C" & .Cells(.Rows.Count, "A").End(xlUp).Row)
            .Formula = "=SUMIF(B:B,B2,A:A)"
            .Value = .Value
        End With
    End With
End Sub

---

或者你可以只放置公式

=SUMIF(B:B,B2,A:A)

到 Excel 中的单元格 C2 并复制下来。

Answer 2

在 C2 中尝试，

=sumifs(a$2:a2, b$2:b2, b2)

根据需要填写。

如果您只希望某个值的最后一个实例显示总和，那么，

=IF(COUNTIF(A$2:A2, A2)=COUNTIF(A:A, A2), SUMIFS(A$2:A2, B$2:B2, B2), TEXT(,))