如果只有 1 个 if 和 1 个 end if，如何解决“如果没有阻塞则结束”？

Question

如果我在 For Each 语句之间有一个 if 语句，这是否会影响我需要放置“end if”的位置以及我正在使用多少个 end if 语句？

我尝试过在结尾处移动并添加更多内容，但没有任何帮助。

Sheets("Arrivals").Select

Dim cel As Range
Dim unit As Range

ParcelCount = Range("BW8").Value
LowerParcelCount = Range("BW5").Value
ThresholdCount = 0

For Each cel In Range("BQ3:BQ78")
    If cel.Value > LowerParcelCount Then
        For Each unit In Range("C3:C78")
            ThresholdCount = ThresholdCount + unit.Value
    End If
Next cel
Next unit

Range("BS16") = ThresholdCount

我希望代码能够运行。如果 BQ3:BQ78 范围内的单元格值符合条件，则 C3:C78 范围内的调用值应与空变量 ThresholdCount 相加。

Answer 1

你错过了下一个单位行：

Option Explicit
Sub Test()

    Sheets("Arrivals").Select

    Dim cel As Range
    Dim unit As Range

    ParcelCount = Range("BW8").Value
    LowerParcelCount = Range("BW5").Value
    ThresholdCount = 0

    For Each cel In Range("BQ3:BQ78")
        If cel.Value > LowerParcelCount Then
            For Each unit In Range("C3:C78")
                ThresholdCount = ThresholdCount + unit.Value
            Next unit
        End If
    Next cel

    Range("BS16") = ThresholdCount


End Sub

你也应该学会缩进你的代码，避免使用.Select并使用Option Explicit声明你的所有变量

这里，你的代码应该是这样的：

Option Explicit
Sub Test()

    Dim ws As Worksheet 'declare your worksheets

    Set ws = ThisWorkbook.Sheets("Arrivals") 'like this you will refer to it using ws

    Dim cel As Range, unit As Range
    Dim ParcelCount As Long, LowerParcelCount As Long, ThresholdCount As Long

    With ws 'you could also use With ThisWorkbook.Sheets("Arrivals") if you are not using that sheet anymore
        ParcelCount = .Range("BW8").Value
        LowerParcelCount = .Range("BW5").Value
        ThresholdCount = 0

        For Each cel In .Range("BQ3:BQ78")
            If cel.Value > LowerParcelCount Then
                For Each unit In .Range("C3:C78")
                    ThresholdCount = ThresholdCount + unit.Value
                Next unit
            End If
        Next cel
        .Range("BS16") = ThresholdCount
    End With

End Sub

如您所见，无需选择工作表到达，因为我们在顶部声明了它并一直使用它的引用，因为所有内容都在 With ws 内