满足 2 个条件时插入行

Question

我创建了下面的代码，其工作方式类似于 IF Col"B" 任何单元格 <> "" 和 Col"L" 任何单元格 = "Leop" 然后将下面的行添加到活动单元格。

我的意思是我想要实现的是在 B 列中包含任何值的特定行之后插入单行，并且如果同一行中的 L 列包含 value =“Leop”。然后在该行之后添加行。

但出现错误。 Compile Error: Invalid use of property xlDown

您的帮助将不胜感激。

从这里：

到这里：

Sub firstcondition()

    Dim ws As Worksheet
    Dim LRow As Long
    Dim rng As Range
    Dim rng2 As Range
    Dim i As Long
    Dim p As Long
    Dim dat As Variant
    Dim datt As Variant
    Dim IRow As Long
    
    Set ws = Thisworkbooks.Sheets("Sheet2")
    
    With ws
    LRow = .Range("A" & .Rows.Count).End(xlUp).Row
    Set rng = .Range("B2:B" & LRow)
    Set rng2 = .Range("L2:L" & LRow)
    
    dat = rng
    datt = rng2
    IRow = Selection.Row
    
    For i = LBound(dat, 1) To UBound(dat, 1)
    For p = LBound(datt, 1) To UBound(datt, 1)
    
        If dat(i, 1) <> "" And datt(p, 1) = "Leop" Then
        Rows(IRow + 1).Select
        Selection.Insert Shift: xlDown
        End If
    
End Sub

它会像公式：

IF(AND(B2<>"",L2="Leop"),"InsertRowBelow to Row 2 If condition is met","")

并将其拖到最后一行。

Answer 1

Thisworkbooks.Sheets("Sheet2") 应该是 Thisworkbook.Sheets("Sheet2") 并且在 Selection.Insert Shift:= xlDown 中缺少 =

插入或删除行会改变最后一行的编号，所以从底部开始向上工作。

Option Explicit
Sub firstcondition()

    Dim ws As Worksheet, LRow As Long, r As Long
    Dim n As Long
    
    Set ws = ThisWorkbook.Sheets("Sheet2")
    With ws
        LRow = .Range("B" & .Rows.Count).End(xlUp).Row
        For r = LRow To 2 Step -1
            If .Cells(r, "B") <> "" And .Cells(r, "L") = "Leop" Then
                .Rows(r + 1).Insert shift:=xlDown
                n = n + 1
            End If
        Next
    End With
    MsgBox n & " rows inserted", vbInformation

End Sub

Answer 2

用自动过滤器试试这个，你不必遍历每一行。所以它会更快地处理更大的数据。

Option Explicit
Sub firstcondition()
Dim ws As Worksheet
    Dim LRow As Long, cl As Range
    Set ws = ThisWorkbook.Sheets("Sheet2")
    LRow = ws.Range("A" & ws.Rows.Count).End(xlUp).Row
    ws.Range("L1:L" & LRow).AutoFilter 1, "Leop"
    
    For Each cl In ws.Range("_FilterDatabase").SpecialCells(12).Cells
        If ws.Range("B" & cl.Row) <> "" Then
            cl.Offset(1).EntireRow.Insert Shift:=xlDown
        End If
    Next
    ws.AutoFilterMode = False
End Sub