如何确定 JVM 上任意格式（JPEG、PNG 等）的图像文件的尺寸？

Question

我想浏览一个目录并挑选出所有图像，然后根据它们的尺寸做一些事情。我可以使用哪些库来执行此操作？

我在 Clojure 工作，但 JVM 上可用的任何东西都是公平的游戏。

提前致谢！

Answer 1

(with-open [r (java.io.FileInputStream. "test.jpeg")]
  (let [image (javax.imageio.ImageIO/read r)]
    [(.getWidth image) (.getHeight image)]))

您可以使用with-open 自动关闭流。

这里是一个使用来遍历目录中一些文件的例子。它假定目录中的所有文件都是图像。示例目录仅包含您的 stackoverflow 头像。

(defn files-in-dir [dir]
  (filter #(not (.isDirectory %))
          (.listFiles (java.io.File. dir))))

(defn figure-out-height-width
  [files]
  (map (fn [file]
         (with-open [r (java.io.FileInputStream. file)]
           (let [img (javax.imageio.ImageIO/read r)]
             [file (.getWidth img) (.getHeight img)])))
       files))

user>(figure-out-height-width (files-in-dir "/home/jmccrary/Downloads/pics/"))
([#<File /home/jmccrary/Downloads/pics/test.jpeg> 32 32])

Answer 2

包裹javax.io 就是您要找的。​​p>

(import 'java.io.File)
(import 'java.io.FileInputStream)
(import 'javax.imageio.ImageIO)

(def img  (ImageIO/read (FileInputStream. (File. "myfile.png"))))

[ (.getWidth img) (.getHeight img)]

• 适用于 png 和 jpg 文件。
• 这是匆忙发布的。在 Clojure 中打开文件并获取 InputStream 有更多惯用的方法。

Answer 3

也许更有效的答案可能是

(ns common.image
  (:require [clojure.java.io :as io])
  (:import (javax.imageio ImageIO)))

(defn dimensions [src]
  (let [res (if (string? src) (io/file (io/resource src)) src)]
    (if res
      (let [image-input-stream (ImageIO/createImageInputStream res)
            readers (ImageIO/getImageReaders image-input-stream)]
        (if-let [r (and (.hasNext readers) (.next readers))]
          (try
            (.setInput r image-input-stream)
            [(.getWidth r 0) (.getHeight r 0)]
            (finally
              (.dispose r)))))
      [0 0])))

这不需要将整个图像读入内存。

改编自https://stackoverflow.com/a/1560052