cljc 宏中的错误处理

Question

我发现在 clj 和 cljs 中定义一个宏来进行错误处理非常棘手。我以为将Exception 与js/Error 交换是一件简单的事情，但结果却比这更复杂。

一开始我是这样尝试的：

(defmacro my-macro
  [& forms]
 `(try
    ~@forms
    (catch #?(:clj Exception :cljs js/Error) e#
      ,,,)))

但这每次都会产生Exception。我很快意识到问题是在编译我的 cljs 文件期间调用了宏，这发生在 clj 环境中。因此，我必须让宏返回一个在运行时解析为正确异常类的表单。我试过这个：

(def exception-class
  #?(:clj Exception :cljs js/Error))

(defmacro my-macro
  [& forms]
 `(try
    ~@forms
    (catch exception-class e#
      ,,,)))

现在它在 cljs 中有效，但在 clj 中无效！！！经过一些实验，我发现 JVM Clojure（显然）不允许您间接引用异常类。您必须直接按名称引用Exception。

所以最后，我决定了：

(def fake-java
  #?(:cljs (clj->js {:lang {:Exception js/Error}})))

(defmacro my-macro
  [& forms]
 `(let [~'java fake-java]
    (try
      ~@forms
      (catch Exception e#
        ,,,))))

Exception 扩展为 java.lang.Exception，现在在运行时在 clj 和 cljs 中解析为正确的异常类。

我的问题是，有没有更好的方法呢？为什么 JVM Clojure 不允许间接引用异常类，而 ClojureScript 允许？

更新

在 ClojureMostly 的帮助下，我已经像这样重构了宏，并且它可以工作：

(defmacro my-macro
  [& forms]
 `(try
    ~@forms
    (catch ~(if (:ns &env) 'js/Error 'Exception) e#
      ,,,)))

Answer 1

您可以重构您的宏，使其以函数调用的形式表达。此函数将接受表单的“thunk”并将其包装在 try 中（而不是直接在宏中执行此操作）。

例如：

(defmacro my-macro [& forms]
  `(my-macro* (fn []
                ~@forms)))

那么你可以将my-macro*定义为：

(defn my-macro* [f]
  (try
    (f)
    (catch #?(:clj Exception :cljs js/Error) e
      ...)))

Answer 2

执行此操作的常用方法是在 defmacro 中的特殊 &env 绑定中使用 check for the :ns key。 Copied from plumatic/schema:

(defn cljs-env?
  "Take the &env from a macro, and tell whether we are expanding into cljs."
  [env]
  (boolean (:ns env)))

(defmacro try-catchall
  "A cross-platform variant of try-catch that catches all exceptions.
   Does not (yet) support finally, and does not need or want an exception class."
  [& body]
  (let [try-body (butlast body)
        [catch sym & catch-body :as catch-form] (last body)]
    (assert (= catch 'catch))
    (assert (symbol? sym))
    (if (cljs-env? &env)
      `(try ~@try-body (~'catch js/Object ~sym ~@catch-body))
      `(try ~@try-body (~'catch Throwable ~sym ~@catch-body)))))

用法：

(macros/try-catchall (f)  (catch e# ::exception))