【问题标题】:Why aren't recursive calls automagically replaced by recur?为什么递归调用不会自动被 recur 替换?
【发布时间】:2011-09-29 15:37:26
【问题描述】:

在以下 (Clojure) SO 问题中:my own interpose function as an exercise

接受的答案是这样说的:

将您的递归调用替换为对 recur 的调用,因为如其所写 会碰到堆栈溢出

(defn foo [stuff]
  (dostuff ... )
  (foo (rest stuff)))

变成:

(defn foo [stuff]
  (dostuff ...)
  (recur (rest stuff)))

避免炸毁堆栈。

这可能是一个愚蠢的问题,但我想知道为什么对 foo 的递归调用不会自动替换为 recur?

另外,我拿了另一个 SO 示例并写了这个(没有故意使用 cond,只是为了尝试一下):

(defn is-member [elem ilist]
  (if (empty? ilist)
    false
    (if (= elem (first ilist))
      true
      (is-member elem (rest ilist)))))

我想知道是否应该用 recur 替换对 is-member 的调用(这似乎也有效)。

在某些情况下你会递归并且特别不应该使用recur?

【问题讨论】:

  • 顺便说一句,我修改为使用 if 而不是 cond 的 is-member 函数(来自另一个 SO 示例)是基本上是我在 Clojure 中的第一个“程序”,可能是假的,所以对 Clojure 新手要温柔; )
  • 我对明确的trues 和falses 过敏,所以更喜欢(defn is-member? [elem ilist] (and (seq ilist) (or (= elem (first ilist)) (recur elem (rest ilist)))))
  • ...如果您想知道何时可以使用尾递归,请看这里:stackoverflow.com/questions/7813497/…

标签: recursion clojure


【解决方案1】:

如果您有尾递归方法,几乎​​没有理由不使用recur,尽管除非您处于对性能敏感的代码区域,否则它不会有什么不同。

我认为基本论点是明确的recur 可以非常清楚地表明函数是否是尾递归的;所有尾递归函数都使用recur,而recur 的所有函数都是尾递归(如果您尝试从非尾位置使用recur,编译器会报错。)所以这有点美感决定。

recur 还有助于将 Clojure 与对所有尾调用执行 TCO 的语言(如 Scheme)区分开来; Clojure 不能有效地做到这一点,因为它的函数被编译为 Java 函数并且 JVM 不支持它。通过将recur 设为特例,希望不会出现过高的期望。

如果是这样设计的,我认为编译器无法为您插入 recur 没有任何技术原因,但也许有人会纠正我。

【讨论】:

  • 因为如果编译器为您切换到recur,那么无论如何您都必须知道/猜测它何时这样做。这样,如果您尝试编写尾递归函数并失败,编译器会通过拒绝运行您的代码来告知您。
【解决方案2】:

我问过 Rich Hickey,他的推理基本上是(我解释一下)

“让特殊情况看起来很特别”

他没有看到在一个特殊情况下大部分时间并离开人们的价值 想知道为什么如果稍后发生变化并且编译器无法保证优化时会破坏堆栈。不合时宜地,它只是为保持语言简单而做出的设计决策之一

【讨论】:

  • +1 给这里的每个人...知道 Rich Hickey 本人在这个话题上所说的话非常酷。现在我的问题是:我不知道选择哪个答案作为“接受”的答案; )
【解决方案3】:

我想知道是否应该用 recur 替换对 is-member 的调用

一般来说,正如 mquander 所说,没有理由不尽可能不使用 recur。对于小输入(几十到几百个元素),它们是相同的,但是没有 recur 的版本会在大输入(几千个元素)上崩溃。

显式递归(即没有'recur')对很多事情都有好处,但遍历长序列并不是其中之一。

在某些情况下您特别不应该使用 recur 吗?

只有当你不能使用它的时候,也就是当

  • 它不是尾递归的 - 即它想对返回值做一些事情。
  • 递归到不同的函数。

一些例子:

 (defn foo [coll] 
  (when coll 
    (println (first coll))
    (recur (next coll)))   ;; OK: Tail recursive

(defn fie [coll]
  (when coll
    (cons (first coll)       
      (fie (next coll))))) ;; Can't use recur: Not tail recursive.   

(defn fum 
  ([coll] 
    (fum coll []))         ;; Can't use recur: Different function.
  ([coll acc] 
    (if (empty? coll) acc
       (recur (next coll)  ;; OK: Tail recursive
          (conj acc (first coll)))))) 

关于为什么在适当的时候不会自动插入 recur:我不知道,但至少有一个积极的副作用是使实际的函数调用在视觉上与非调用不同(即 recur)。

由于这可能是“工作”和“因 StackOverflowError 崩溃”之间的区别,所以我认为将其明确化(在代码中可见)而不是隐式(您必须从第二个开始)是一个公平的设计选择当编译器没有按预期工作时猜测编译器。

【讨论】:

  • ... 并且,如果 tail 递归到不同的函数,您可以使用trampoline。
猜你喜欢
  • 2022-11-10
  • 2013-11-25
  • 1970-01-01
  • 1970-01-01
  • 2015-03-02
  • 2013-09-10
  • 1970-01-01
  • 2012-01-31
  • 2016-02-04
相关资源
最近更新 更多