关闭 Emacs 中的自动 lambda 字符

Question

我安装的 GNU Emacs 24.3.1 是“有用地”将单词“lambda”（在 python 模式中）和“fn”（在 clojure 模式中）转换为希腊符号 λ。我敢肯定这会让一些人高兴，但我不是其中之一。 :)

有没有 Emacs 黑客知道如何关闭这个不需要的功能？

我在init.el 中尝试了以下方法，但无济于事：

(defconst keywords-to-remove (lambda fn))
(font-lock-remove-keywords 'clojure-mode keywords-to-remove)
(font-lock-remove-keywords 'lisp-mode keywords-to-remove)
(font-lock-remove-keywords 'python-mode keywords-to-remove)

这是我init.el的当前内容：

(require 'package)
(add-to-list 'package-archives
             '("marmalade" . "http://marmalade-repo.org/packages/") t)

(package-initialize)

(when (not package-archive-contents)
  (package-refresh-contents))

(defvar my-packages '(starter-kit
                      starter-kit-lisp
                      starter-kit-bindings
                      auto-complete
                      slime
                      ac-slime
                      rainbow-delimiters
                      clojure-mode
                      nrepl))

(dolist (p my-packages)
  (when (not (package-installed-p p))
    (package-install p)))

(global-set-key (kbd "<C-tab>") 'next-multiframe-window)

(require 'auto-complete-config)
(add-to-list 'ac-dictionary-directories "~/.emacs.d/ac-dict")
(ac-config-default)
(setq ac-delay 0.2) ;; eclipse uses 500ms

(add-to-list 'load-path "~/.emacs.d/ac-slime")
(require 'ac-slime)
(add-hook 'slime-mode-hook 'set-up-slime-ac)
(add-hook 'slime-repl-mode-hook 'set-up-slime-ac)

(setq default-truncate-lines t)

(defun indent-buffer ()
  "Indents an entire buffer using the default intenting scheme."
  (interactive)
  (save-excursion
    (delete-trailing-whitespace)
    (indent-region (point-min) (point-max) nil)
    (untabify (point-min) (point-max))))

(require 'rainbow-delimiters)
(global-rainbow-delimiters-mode)

(require 'color-theme)
(eval-after-load "color-theme"
  '(progn
     (color-theme-initialize)
     (color-theme-ld-dark)))

(add-to-list 'auto-mode-alist '("\\.cljs\\'" . clojure-mode))

;; Allow input to be sent to somewhere other than inferior-lisp
;;
;; This is a total hack: we're hardcoding the name of the shell buffer
(defun shell-send-input (input)
  "Send INPUT into the *shell* buffer and leave it visible."
  (save-selected-window
    (switch-to-buffer-other-window "*shell*")
    (goto-char (point-max))
    (insert input)
    (comint-send-input)))

(defun defun-at-point ()
  "Return the text of the defun at point."
  (apply #'buffer-substring-no-properties
         (region-for-defun-at-point)))

(defun region-for-defun-at-point ()
  "Return the start and end position of defun at point."
  (save-excursion
    (save-match-data
      (end-of-defun)
      (let ((end (point)))
        (beginning-of-defun)
        (list (point) end)))))

(defun expression-preceding-point ()
  "Return the expression preceding point as a string."
  (buffer-substring-no-properties
   (save-excursion (backward-sexp) (point))
   (point)))

(defun shell-eval-last-expression ()
  "Send the expression preceding point to the *shell* buffer."
  (interactive)
  (shell-send-input (expression-preceding-point)))

(defun shell-eval-defun ()
  "Send the current toplevel expression to the *shell* buffer."
  (interactive)
  (shell-send-input (defun-at-point)))

(add-hook 'clojure-mode-hook
          (lambda ()
             (define-key clojure-mode-map (kbd "C-c e") 'shell-eval-last-expression)
             (define-key clojure-mode-map (kbd "C-c x") 'shell-eval-defun)))

Answer 1

如果您使用 starter-kit，那么您还可以通过以下方式关闭 esk-pretty-lambdas 功能：

(remove-hook 'prog-mode-hook 'esk-pretty-lambdas)

在您的 dot emacs 或 init 文件中。

Answer 2

Emacs-24.4 有一个新的全局次要模式prettify-symbols-mode 来控制它。我建议您联系您的主要模式的维护者，并要求他们在定义此次要模式时尝试并遵守它。