【问题标题】:Initializing elements of a map conditionally in Clojure在 Clojure 中有条件地初始化地图的元素
【发布时间】:2012-01-24 19:40:27
【问题描述】:

我正在寻找在初始化/定义地图时有条件地避免向地图添加元素的最佳方式。在这种情况下,如果键的值为 nil,我想避免将元素添加到地图中。

(defn create-record [data]
  (let [res {
    :username (data :username)
    :first-name (get-in data [:user-info :name :first])
    :last-name (get-in data [:user-info :name :last])
    :gender (get-in data [:user-info :sex])
   }])
)

如果登录结果为零(数据中的性别字段不存在),我不想在地图中添加性别。创建地图时有没有办法做到这一点?我可以在创建映射后删除值为 nil 的所有键,但在某些情况下,我希望某些键具有 nil 值,而其他键则根本不在映射中(如果它们具有 nil 值)。

【问题讨论】:

  • 旁白:“性别”!=“性别”

标签: clojure


【解决方案1】:

对于这些可选参数,我会使用merge 和when-let 的组合。

核心思想是为每个可选参数合并单个元素映射或 nil。合并 nil 不会有任何作用,因此您不会在地图中看到 nil。

(defn create-record [data]
  (let [res (merge {:username (data :username)
                    :first-name (get-in data [:user-info :name :first])
                    :last-name (get-in data [:user-info :name :last])}
                   (when-let [gender (get-in data [:user-info :sex])]
                     {:gender gender}))]
    res))

根据您需要执行此操作的频率,我建议您围绕 when-let 编写一个简短的宏或函数,以使代码更简洁。

【讨论】:

  • 谢谢,这很好 - 但是为什么多余的 (let [res ... res) 包装器?
  • @Alex 我让代码尽可能与他的相似。我假设他可能在分配后对结果做了其他事情,所以我把它留在了那里。你是对的,虽然没有必要。
  • 啊,谢谢,有道理@deterb。我担心我错过了什么。
【解决方案2】:
(cond-> {:username   (data :username)
         :first-name (get-in data [:user-info :name :first])
         :last-name  (get-in data [:user-info :name :last])}
    (get-in data [:user-info :sex]) (assoc :gender (get-in data [:user-info :sex])))

【讨论】:

    【解决方案3】:
    (defn create-record [data]   
       (merge {:username   (data :username)
               :first-name (get-in data [:user-info :name :first])
               :last-name  (get-in data [:user-info :name :last])}
               (when       
                 (get-in data [:user-info :sex]) 
                 {:gender (get-in data [:user-info :sex])})))
    

    只需为您要检查的每个元素添加when 是否不是nil,然后它将返回一个要合并的映射或nil,这不会影响返回映射值。

    您可以将多个映射合并在一起,因此要合并的映射没有限制,并且您可以为每个不是nil 的元素返回一个单独的映射。

    【讨论】:

      【解决方案4】:

      你可以做类似的事情

      (let [not-nils #{:gender}]
        (defn create-record [data]
          (into {} (for [[k v] {:username (data :username)
                                :first-name (get-in data [:user-info :name :first])
                                :last-name (get-in data [:user-info :name :last])
                                :gender (get-in data [:user-info :sex])}
                         :when (not (and (nil? v) (not-nils k)))]
                     [k v]))))
      

      【讨论】:

        【解决方案5】:

        构建一个映射并dissocing 基于谓词(此处为nil?)您要对其施加条件的键可能是最简单的方法(注意。此函数仅测试作为参数明确提及的键;那些未提及的永远不会被删除,无论附加到它们的值是否满足谓词):

        (defn dissoc-when
          "Dissoc those keys from m which are mentioned among ks and whose
           values in m satisfy pred."
          [pred m & ks]
          (apply dissoc m (filter #(pred (m %)) ks)))
        

        在 REPL:

        user> (dissoc-when nil? {:foo nil :bar true :quux nil} :foo :bar)
        {:quux nil, :bar true}
        

        虽然一般来说,如果您希望使用大量代表某种特定类型的现实世界实体的地图,您可能希望使用记录 - 然后您可以跳过所有 nils 在以下阶段您从输入映射中提取值,因为当作为映射查看时,记录似乎总是包含与其字段对应的键。例如

        (defrecord Person [username first-name last-name])
        

        然后你可以分解出地图之间“模式转换”的逻辑:

        (defn translate-map
          "Transforms the data map in accordance with the spec in table.
           Skips nil-valued entries."
          [data table]
          (->> table
               (keep (fn [[to from]]
                       (when-let [from-val (get-in data from)]
                         [to from-val])))
               (into {})))
        

        现在你的create-record 函数变成了translate-map 和map->Person 的组合:

        (defn create-person [data]
          (map->Person
           (translate-map data {:username [:username]
                                :first-name [:user-info :name :first]
                                :last-name [:user-info :name :last]
                                :gender [:user-info :sex]})))
        

        如果您确实更喜欢使用常规地图,则可以使用类似以下的内容来代替等效输出:

        (defn create-person [data]
          (merge (zipmap [:username :first-name :last-name] (repeat nil))
                 (translate-map data {:username [:username]
                                      :first-name [:user-info :name :first]
                                      :last-name [:user-info :name :last]
                                      :gender [:user-info :sex]})))
        

        在 REPL(Clojure 1.3 中的记录版本):

        user> (create-person {:username "jsmith"
                              :user-info {:name {:first "John" :last "Smith"}}})
        #user.Person{:username "jsmith", :first-name "John", :last-name "Smith"}
        user> (create-person {:username "jsmith"
                              :user-info {:name {:first "John" :last "Smith"}
                                          :sex :male}})
        #user.Person{:username "jsmith", :first-name "John", :last-name "Smith", :gender :male}
        

        【讨论】:

          【解决方案6】:
          (defn create-record [data]
            (let [gender (get-in data [:user-info :sex])]
              (->> {:username (data :username)
                    :first-name (get-in data [:user-info :name :first])
                    :last-name (get-in data [:user-info :name :last])}
                   (#(if gender (assoc % :gender gender) %)))))
          

          【讨论】:

            【解决方案7】:

            您可以定义您的字段以及哪些字段是可选的:

            (def fields
            [[:username   [:username]]
             [:first-name [:user-info :name :first]]
             [:sex        [:user-info :sex]          true]])
            

            然后编写一个函数来使用该信息:

            (defn create-record [data keys]
              (->>
                (for [[n k ignore-nil?] keys 
                        :let [v (get-in data k)] 
                        :when (or (not ignore-nil?) v)]
                  [n v])
                (into {})))
            

            它会像这样工作:

            ; If :sex is missing don't create a field
            user=> (create-record {:username "dr" :user-info { :name {:first "Dave"} }} fields)
            {:username "dr", :first-name "Dave"}
            
            user=> (create-record {:username "dr" :user-info { :name {:first "Dave"} :sex :m }} fields)
            {:username "dr", :first-name "Dave", :sex :m}
            
            ; If :first is missing, create a nil field
            user=> (create-record {:username "dr" :user-info { :name {} :sex :m }} fields)
            {:username "dr", :first-name nil, :sex :m}
            

            根据需要修改:)

            【讨论】:

              【解决方案8】:

              这是一个尝试:

              (defn exclude-nils-for [m kw-set] 
                  (apply hash-map (apply concat (remove (fn [[k v]] (and (kw-set k) (nil? v))) m))))
              

              测试:

              user> (exclude-nils-for {:gender "m" :name "Thomas" :age "24"} #{})
              {:age "21", :gender "m", :name "Thomas"}
              user> (exclude-nils-for {:gender "m" :name "Thomas" :age "24"} #{:name})
              {:age "21", :gender "m", :name "Thomas"}
              user> (exclude-nils-for {:gender "m" :name nil :age "24"} #{:name})
              {:age "21", :gender "m"}
              user> (exclude-nils-for {:gender "m" :name nil :age nil} #{:age})
              {:gender "m", :name nil}
              

              【讨论】:

              • 您可能希望将flatten 替换为apply concat,否则更复杂的值会导致问题(尝试在第一个示例中将:foo [1 2] 添加到地图中)。 (或者也许打开一层括号并使其成为apply (comp hash-map concat)。)另外,我会添加一个测试以排除nil 值 not 的情况(尽管这确实有效)。
              • 完成。感谢您的评论!
              猜你喜欢
              • 1970-01-01
              • 1970-01-01
              • 1970-01-01
              • 2013-10-16
              • 2016-12-10
              • 1970-01-01
              • 1970-01-01
              • 2017-08-19
              • 2019-06-05
              相关资源
              最近更新 更多